(*

 * Hedgewars, a free turn based strategy game

 * Copyright (c) 2004-2014 Andrey Korotaev <unC0Rr@gmail.com>

 *

 * This program is free software; you can redistribute it and/or modify

 * it under the terms of the GNU General Public License as published by

 * the Free Software Foundation; version 2 of the License

 *

 * This program is distributed in the hope that it will be useful,

 * but WITHOUT ANY WARRANTY; without even the implied warranty of

 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

 * GNU General Public License for more details.

 *

 * You should have received a copy of the GNU General Public License

 * along with this program; if not, write to the Free Software

 * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA

 *)

{$INCLUDE "options.inc"}

unit uScript;

(*

 * This unit defines, implements and registers functions and

 * variables/constants bindings for usage in Lua scripts.

 *

 * Please keep http://code.google.com/p/hedgewars/wiki/LuaAPI up to date!

 *

 * Note: If you add a new function, make sure to test if _all_ parameters

 *       work as intended! (Especially conversions errors can sneak in

 *       unnoticed and render the parameter useless!)

 *)

interface

procedure ScriptPrintStack;

procedure ScriptClearStack;

procedure ScriptLoad(name : shortstring);

procedure ScriptOnPreviewInit;

procedure ScriptOnGameInit;

procedure ScriptOnScreenResize;

procedure ScriptSetInteger(name : shortstring; value : LongInt);

procedure ScriptSetString(name : shortstring; value : shortstring);

procedure ScriptCall(fname : shortstring);

function ScriptCall(fname : shortstring; par1: LongInt) : LongInt;

function ScriptCall(fname : shortstring; par1, par2: LongInt) : LongInt;

function ScriptCall(fname : shortstring; par1, par2, par3: LongInt) : LongInt;

function ScriptCall(fname : shortstring; par1, par2, par3, par4 : LongInt) : LongInt;

function ScriptExists(fname : shortstring) : boolean;

//function ParseCommandOverride(key, value : shortstring) : shortstring;  This did not work out well

procedure initModule;

procedure freeModule;

implementation

{$IFDEF USE_LUA_SCRIPT}

uses LuaPas,

    uConsole,

    uConsts,

    uGears,

    uGearsList,

    uGearsUtils,

    uFloat,

    uWorld,

    uAmmos,

    uTeams,

    uSound,

    uChat,

    uStats,

    uStore,

    uRandom,

    uTypes,

    uVariables,

    uCommands,

    uUtils,

    uCaptions,

    uDebug,

    uCollisions,

    uRenderUtils,

    uTextures,

    uLandGraphics,

    SysUtils,

    uIO,

    uVisualGearsList,

    uGearsHandlersMess,

    uPhysFSLayer

{$IFNDEF PAS2C}

    , typinfo

{$ENDIF}

    ;

var luaState : Plua_State;

    ScriptAmmoLoadout : shortstring;

    ScriptAmmoProbability : shortstring;

    ScriptAmmoDelay : shortstring;

    ScriptAmmoReinforcement : shortstring;

    ScriptLoaded : boolean;

    mapDims : boolean;

procedure ScriptPrepareAmmoStore; forward;

procedure ScriptApplyAmmoStore; forward;

procedure ScriptSetAmmo(ammo : TAmmoType; count, probability, delay, reinforcement: Byte); forward;

procedure ScriptSetAmmoDelay(ammo : TAmmoType; delay: Byte); forward;

procedure LuaError(s: shortstring);

begin

    s:= 'Lua-script error: ' + s;

    WriteLnToConsole(s);

    AddChatString(#5 + s);

    if cTestLua then

        halt(rtnTestLuaErr);

end;

procedure LuaCallError(error, call, paramsyntax: shortstring);

begin

    LuaError(call + ': ' + error + '       function syntax: ' + call + ' ( ' + paramsyntax + ' )');

end;

procedure LuaParameterCountError(expected, call, paramsyntax: shortstring; wrongcount: LongInt); inline;

begin

    // TODO: i18n?

    LuaCallError('Wrong number of parameters! (is: ' + inttostr(wrongcount) + ', should be: '+ expected + ')', call, paramsyntax);

end;

// TODO remove this precedure after all references have been changed to one of the checks below

procedure LuaParameterCountError(call, paramsyntax: shortstring; wrongcount: LongInt); inline;

begin

    LuaCallError('Wrong number of parameters! (actual: ' + inttostr(wrongcount) + ')', call, paramsyntax);

end;

// compare with allowed count

function CheckLuaParameterCount(L : Plua_State; count: LongInt; call, paramsyntax: shortstring): boolean; inline;

var c: LongInt;

begin

    c:= lua_gettop(L);

    if c <> count then

        begin

        LuaParameterCountError('exactly ' + inttostr(count), call, paramsyntax, c);

        exit(false);

        end;

    CheckLuaParameterCount:= true;

end;

// check if is either count1 or count2

function CheckAndFetchLuaParameterCount(L : Plua_State; count1, count2: LongInt; call, paramsyntax: shortstring; out actual: LongInt): boolean; inline;

begin

    actual:= lua_gettop(L);

    if (actual <> count1) and (actual <> count2) then

        begin

        LuaParameterCountError('either ' + inttostr(count1) + ' or ' + inttostr(count2), call, paramsyntax, actual);

        exit(false);

        end;

    CheckAndFetchLuaParameterCount:= true;

end;

// check if is same or higher as minCount

function CheckAndFetchLuaParameterCount(L : Plua_State; minCount: LongInt; call, paramsyntax: shortstring; out actual: LongInt): boolean; inline;

begin

    actual:= lua_gettop(L);

    if (actual < minCount) then

        begin

        LuaParameterCountError(inttostr(minCount) + ' or more', call, paramsyntax, actual);

        exit(false);

        end;

    CheckAndFetchLuaParameterCount:= true;

end;

function LuaToGearTypeOrd(L : Plua_State; i: LongInt; call, paramsyntax: shortstring): LongInt; inline;

begin

    if lua_isnoneornil(L, i) then i:= -1

    else i:= lua_tointeger(L, i);

    if (i < ord(Low(TGearType))) or (i > ord(High(TGearType))) then

        begin

        LuaCallError('Invalid gearType!', call, paramsyntax);

        LuaToGearTypeOrd:= -1;

        end

    else

        LuaToGearTypeOrd:= i;

end;

function LuaToVisualGearTypeOrd(L : Plua_State; i: LongInt; call, paramsyntax: shortstring): LongInt; inline;

begin

    if lua_isnoneornil(L, i) then i:= -1

    else i:= lua_tointeger(L, i);

    if (i < ord(Low(TVisualGearType))) or (i > ord(High(TVisualGearType))) then

        begin

        LuaCallError('Invalid visualGearType!', call, paramsyntax);

        LuaToVisualGearTypeOrd:= -1;

        end

    else

        LuaToVisualGearTypeOrd:= i;

end;

function LuaToAmmoTypeOrd(L : Plua_State; i: LongInt; call, paramsyntax: shortstring): LongInt; inline;

begin

    if lua_isnoneornil(L, i) then i:= -1

    else i:= lua_tointeger(L, i);

    if (i < ord(Low(TAmmoType))) or (i > ord(High(TAmmoType))) then

        begin

        LuaCallError('Invalid ammoType!', call, paramsyntax);

        LuaToAmmoTypeOrd:= -1;

        end

    else

        LuaToAmmoTypeOrd:= i;

end;

function LuaToStatInfoTypeOrd(L : Plua_State; i: LongInt; call, paramsyntax: shortstring): LongInt; inline;

begin

    if lua_isnoneornil(L, i) then i:= -1

    else i:= lua_tointeger(L, i);

    if (i < ord(Low(TStatInfoType))) or (i > ord(High(TStatInfoType))) then

        begin

        LuaCallError('Invalid statInfoType!', call, paramsyntax);

        LuaToStatInfoTypeOrd:= -1;

        end

    else

        LuaToStatInfoTypeOrd:= i;

end;

function LuaToSoundOrd(L : Plua_State; i: LongInt; call, paramsyntax: shortstring): LongInt; inline;

begin

    if lua_isnoneornil(L, i) then i:= -1

    else i:= lua_tointeger(L, i);

    if (i < ord(Low(TSound))) or (i > ord(High(TSound))) then

        begin

        LuaCallError('Invalid soundId!', call, paramsyntax);

        LuaToSoundOrd:= -1;

        end

    else

        LuaToSoundOrd:= i;

end;

function LuaToHogEffectOrd(L : Plua_State; i: LongInt; call, paramsyntax: shortstring): LongInt; inline;

begin

    if lua_isnoneornil(L, i) then i:= -1

    else i:= lua_tointeger(L, i);

    if (i < ord(Low(THogEffect))) or (i > ord(High(THogEffect))) then

        begin

        LuaCallError('Invalid gear type!', call, paramsyntax);

        LuaToHogEffectOrd:= -1;

        end

    else

        LuaToHogEffectOrd:= i;

end;

function LuaToCapGroupOrd(L : Plua_State; i: LongInt; call, paramsyntax: shortstring): LongInt; inline;

begin

    if lua_isnoneornil(L, i) then i:= -1

    else i:= lua_tointeger(L, i);

    if (i < ord(Low(TCapGroup))) or (i > ord(High(TCapGroup))) then

        begin

        LuaCallError('Invalid capgroup type!', call, paramsyntax);

        LuaToCapGroupOrd:= -1;

        end

    else

        LuaToCapGroupOrd:= i;

end;

function LuaToSpriteOrd(L : Plua_State; i: LongInt; call, paramsyntax: shortstring): LongInt; inline;

begin

    if lua_isnoneornil(L, i) then i:= -1

    else i:= lua_tointeger(L, i);

    if (i < ord(Low(TSprite))) or (i > ord(High(TSprite))) then

        begin

        LuaCallError('Invalid sprite id!', call, paramsyntax);

        LuaToSpriteOrd:= -1;

        end

    else

        LuaToSpriteOrd:= i;

end;

// wrapped calls //

// functions called from Lua:

// function(L : Plua_State) : LongInt; Cdecl;

// where L contains the state, returns the number of return values on the stack

// call lua_gettop(L) to receive number of parameters passed

function lc_band(L: PLua_State): LongInt; Cdecl;

begin

    if CheckLuaParameterCount(L, 2, 'band', 'value1, value2') then

        lua_pushinteger(L, lua_tointeger(L, 2) and lua_tointeger(L, 1))

    else

        lua_pushnil(L);

    lc_band := 1;

end;

function lc_bor(L: PLua_State): LongInt; Cdecl;

begin

    if CheckLuaParameterCount(L, 2, 'bor', 'value1, value2') then

        lua_pushinteger(L, lua_tointeger(L, 2) or lua_tointeger(L, 1))

    else

        lua_pushnil(L);

    lc_bor := 1;

end;

function lc_bnot(L: PLua_State): LongInt; Cdecl;

begin

    if CheckLuaParameterCount(L, 1, 'bnot', 'value') then

        lua_pushinteger(L, (not lua_tointeger(L, 1)))

    else

        lua_pushnil(L);

    lc_bnot := 1;

end;

function lc_div(L: PLua_State): LongInt; Cdecl;

begin

    if CheckLuaParameterCount(L, 2, 'div', 'dividend, divisor') then

        lua_pushinteger(L, lua_tointeger(L, 1) div lua_tointeger(L, 2))

    else

        lua_pushnil(L);

    lc_div := 1;

end;

function lc_getinputmask(L : Plua_State) : LongInt; Cdecl;

begin

    if CheckLuaParameterCount(L, 0, 'GetInputMask', '') then

        lua_pushinteger(L, InputMask);

    lc_getinputmask:= 1

end;

function lc_setinputmask(L : Plua_State) : LongInt; Cdecl;

begin

    if CheckLuaParameterCount(L, 1, 'SetInputMask', 'mask') then

        InputMask:= lua_tointeger(L, 1);

    lc_setinputmask:= 0

end;

function lc_writelntoconsole(L : Plua_State) : LongInt; Cdecl;

begin

    if CheckLuaParameterCount(L, 1, 'WriteLnToConsole', 'string') then

        WriteLnToConsole('Lua: ' + lua_tostring(L ,1));

    lc_writelntoconsole:= 0;

end;

function lc_parsecommand(L : Plua_State) : LongInt; Cdecl;

var t: PChar;

    i,c: LongWord;

    s: shortstring;

begin

    if CheckLuaParameterCount(L, 1, 'ParseCommand', 'string') then

        begin

        t:= lua_tolstring(L, 1, Psize_t(@c));

        for i:= 1 to c do s[i]:= t[i-1];

        s[0]:= char(c);

        ParseCommand(s, true, true);

        end;

    lc_parsecommand:= 0;

end;

function lc_showmission(L : Plua_State) : LongInt; Cdecl;

begin

    if CheckLuaParameterCount(L, 5, 'ShowMission', 'caption, subcaption, text, icon, time') then

        ShowMission(lua_tostringA(L, 1), lua_tostringA(L, 2), lua_tostringA(L, 3), lua_tointeger(L, 4), lua_tointeger(L, 5));

    lc_showmission:= 0;

end;

function lc_hidemission(L : Plua_State) : LongInt; Cdecl;

begin

    L:= L; // avoid compiler hint

    HideMission;

    lc_hidemission:= 0;

end;

function lc_enablegameflags(L : Plua_State) : LongInt; Cdecl;

var i, n : integer;

begin

    // can have 1 or more arguments

    if CheckAndFetchLuaParameterCount(L, 1, 'EnableGameFlags', 'gameFlag, ... ', n) then

        begin

        for i:= 1 to n do

            GameFlags := GameFlags or LongWord(lua_tointeger(L, i));

        ScriptSetInteger('GameFlags', GameFlags);

        end;

    lc_enablegameflags:= 0;

end;

function lc_disablegameflags(L : Plua_State) : LongInt; Cdecl;

var i , n: integer;

begin

    // can have 1 or more arguments

    if CheckAndFetchLuaParameterCount(L, 1, 'DisableGameFlags', 'gameFlag, ... ', n) then

        begin

        for i:= 1 to n do

            GameFlags := GameFlags and (not LongWord(lua_tointeger(L, i)));

        ScriptSetInteger('GameFlags', GameFlags);

        end;

    lc_disablegameflags:= 0;

end;

function lc_cleargameflags(L : Plua_State) : LongInt; Cdecl;

begin

    if CheckLuaParameterCount(L, 0, 'ClearGameFlags', '') then

        begin

        GameFlags:= 0;

        ScriptSetInteger('GameFlags', GameFlags);

        end;

    lc_cleargameflags:= 0;

end;

function lc_getgameflag(L : Plua_State) : LongInt; Cdecl;

begin

    if CheckLuaParameterCount(L, 1, 'GetGameFlag', 'gameflag') then

        lua_pushboolean(L, (GameFlags and LongWord(lua_tointeger(L, 1)) <> 0))

    else

        lua_pushnil(L);

    lc_getgameflag:= 1;

end;

function lc_addcaption(L : Plua_State) : LongInt; Cdecl;

var cg: LongInt;

const

    call = 'AddCaption';

    params = 'text [, color, captiongroup]';

begin

    if CheckAndFetchLuaParameterCount(L, 1, 3, call, params, cg) then

        begin

        if cg = 1 then

            AddCaption(lua_tostringA(L, 1), cWhiteColor, capgrpMessage)

        else

            begin

            cg:= LuaToCapGroupOrd(L, 3, call, params);

            if cg >= 0 then

                AddCaption(lua_tostringA(L, 1), lua_tointeger(L, 2) shr 8, TCapGroup(cg));

            end

        end;

    lc_addcaption:= 0;

end;

function lc_campaignlock(L : Plua_State) : LongInt; Cdecl;

begin

    if CheckLuaParameterCount(L, 1, 'CampaignLock', 'TODO') then

        begin

        // TODO

        end;

    lc_campaignlock:= 0;

end;

function lc_campaignunlock(L : Plua_State) : LongInt; Cdecl;

begin

    if CheckLuaParameterCount(L, 1, 'CampaignUnlock', 'TODO') then

        begin

        // TODO

        end;

    lc_campaignunlock:= 0;

end;

function lc_spawnfakehealthcrate(L: Plua_State) : LongInt; Cdecl;

var gear: PGear;

begin

    if CheckLuaParameterCount(L, 4,'SpawnFakeHealthCrate', 'x, y, explode, poison') then

        begin

        gear := SpawnFakeCrateAt(lua_tointeger(L, 1), lua_tointeger(L, 2),

        HealthCrate, lua_toboolean(L, 3), lua_toboolean(L, 4));

        lua_pushinteger(L, gear^.uid);

        end

    else

        lua_pushnil(L);

    lc_spawnfakehealthcrate := 1;

end;

function lc_spawnfakeammocrate(L: PLua_State): LongInt; Cdecl;

var gear: PGear;

begin

    if CheckLuaParameterCount(L, 4,'SpawnFakeAmmoCrate', 'x, y, explode, poison') then

        begin

        gear := SpawnFakeCrateAt(lua_tointeger(L, 1), lua_tointeger(L, 2),

        AmmoCrate, lua_toboolean(L, 3), lua_toboolean(L, 4));

        lua_pushinteger(L, gear^.uid);

        end

    else

        lua_pushnil(L);

    lc_spawnfakeammocrate := 1;

end;