(*

 * Hedgewars, a free turn based strategy game

 * Copyright (c) 2004-2014 Andrey Korotaev <unC0Rr@gmail.com>

 *

 * This program is free software; you can redistribute it and/or modify

 * it under the terms of the GNU General Public License as published by

 * the Free Software Foundation; version 2 of the License

 *

 * This program is distributed in the hope that it will be useful,

 * but WITHOUT ANY WARRANTY; without even the implied warranty of

 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

 * GNU General Public License for more details.

 *

 * You should have received a copy of the GNU General Public License

 * along with this program; if not, write to the Free Software

 * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA

 *)

{$INCLUDE "options.inc"}

unit uScript;

(*

 * This unit defines, implements and registers functions and

 * variables/constants bindings for usage in Lua scripts.

 *

 * Please keep http://code.google.com/p/hedgewars/wiki/LuaAPI up to date!

 *

 * Note: If you add a new function, make sure to test if _all_ parameters

 *       work as intended! (Especially conversions errors can sneak in

 *       unnoticed and render the parameter useless!)

 *)

interface

procedure ScriptPrintStack;

procedure ScriptClearStack;

procedure ScriptLoad(name : shortstring);

procedure ScriptOnGameInit;

procedure ScriptOnScreenResize;

procedure ScriptSetInteger(name : shortstring; value : LongInt);

procedure ScriptSetString(name : shortstring; value : shortstring);

procedure ScriptCall(fname : shortstring);

function ScriptCall(fname : shortstring; par1: LongInt) : LongInt;

function ScriptCall(fname : shortstring; par1, par2: LongInt) : LongInt;

function ScriptCall(fname : shortstring; par1, par2, par3: LongInt) : LongInt;

function ScriptCall(fname : shortstring; par1, par2, par3, par4 : LongInt) : LongInt;

function ScriptExists(fname : shortstring) : boolean;

//function ParseCommandOverride(key, value : shortstring) : shortstring;  This did not work out well

procedure initModule;

procedure freeModule;

implementation

{$IFDEF USE_LUA_SCRIPT}

uses LuaPas,

    uConsole,

    uConsts,

    uGears,

    uGearsList,

    uGearsUtils,

    uFloat,

    uWorld,

    uAmmos,

    uTeams,

    uSound,

    uChat,

    uStats,

    uStore,

    uRandom,

    uTypes,

    uVariables,

    uCommands,

    uUtils,

    uCaptions,

    uDebug,

    uCollisions,

    uRenderUtils,

    uTextures,

    uLandGraphics,

    SysUtils,

    uIO,

    uVisualGearsList,

    uGearsHandlersMess,

    uPhysFSLayer

{$IFNDEF PAS2C}

    , typinfo

{$ENDIF}

    ;

var luaState : Plua_State;

    ScriptAmmoLoadout : shortstring;

    ScriptAmmoProbability : shortstring;

    ScriptAmmoDelay : shortstring;

    ScriptAmmoReinforcement : shortstring;

    ScriptLoaded : boolean;

    mapDims : boolean;

procedure ScriptPrepareAmmoStore; forward;

procedure ScriptApplyAmmoStore; forward;

procedure ScriptSetAmmo(ammo : TAmmoType; count, probability, delay, reinforcement: Byte); forward;

procedure ScriptSetAmmoDelay(ammo : TAmmoType; delay: Byte); forward;

procedure LuaError(s: shortstring);

begin

    WriteLnToConsole(s);

    AddChatString(#5 + s);

    if cTestLua then

        halt(rtnTestLuaErr);

end;

procedure LuaParameterCountError(call, paramsyntax: shortstring; wrongcount: LongInt);

begin

    // TODO: i18n?

    LuaError('Lua: Wrong number of parameters (' + inttostr(wrongcount) + ') passed to ' + call + '!     syntax: ' + call + ' ( ' + paramsyntax + ' )');

end;

// wrapped calls //

// functions called from Lua:

// function(L : Plua_State) : LongInt; Cdecl;

// where L contains the state, returns the number of return values on the stack

// call lua_gettop(L) to receive number of parameters passed

function lc_band(L: PLua_State): LongInt; Cdecl;

begin

    if lua_gettop(L) <> 2 then

        begin

        LuaParameterCountError('band', 'value1, value2', lua_gettop(L));

        lua_pushnil(L);

        end

    else

        lua_pushinteger(L, lua_tointeger(L, 2) and lua_tointeger(L, 1));

    lc_band := 1;

end;

function lc_bor(L: PLua_State): LongInt; Cdecl;

begin

    if lua_gettop(L) <> 2 then

        begin

        LuaParameterCountError('bor', 'value1, value2', lua_gettop(L));

        lua_pushnil(L);

        end

    else

        lua_pushinteger(L, lua_tointeger(L, 2) or lua_tointeger(L, 1));

    lc_bor := 1;

end;

function lc_bnot(L: PLua_State): LongInt; Cdecl;

begin

    if lua_gettop(L) <> 1 then

        begin

        LuaParameterCountError('bnot', 'value', lua_gettop(L));

        lua_pushnil(L);

        end

    else

        lua_pushinteger(L, (not lua_tointeger(L, 1)));

    lc_bnot := 1;

end;

function lc_div(L: PLua_State): LongInt; Cdecl;

begin

    if lua_gettop(L) <> 2 then

        begin

        LuaParameterCountError('div', 'dividend, divisor', lua_gettop(L));

        lua_pushnil(L);

        end

    else

        lua_pushinteger(L, lua_tointeger(L, 1) div lua_tointeger(L, 2));

    lc_div := 1;

end;

function lc_getinputmask(L : Plua_State) : LongInt; Cdecl;

begin

    if lua_gettop(L) <> 0 then

        LuaParameterCountError('GetInputMask', '', lua_gettop(L))

    else

        lua_pushinteger(L, InputMask);

    lc_getinputmask:= 1

end;

function lc_setinputmask(L : Plua_State) : LongInt; Cdecl;

begin

    if lua_gettop(L) <> 1 then

        LuaParameterCountError('SetInputMask', 'mask', lua_gettop(L))

    else

        InputMask:= lua_tointeger(L, 1);

    lc_setinputmask:= 0

end;

function lc_writelntoconsole(L : Plua_State) : LongInt; Cdecl;

begin

    if lua_gettop(L) = 1 then

        begin

        WriteLnToConsole('Lua: ' + lua_tostring(L ,1));

        end

    else

        LuaParameterCountError('WriteLnToConsole', 'string', lua_gettop(L));

    lc_writelntoconsole:= 0;

end;

function lc_parsecommand(L : Plua_State) : LongInt; Cdecl;

var t: PChar;

    i,c: LongWord;

    s: shortstring;

begin

    if lua_gettop(L) = 1 then

        begin

        t:= lua_tolstring(L, 1, Psize_t(@c));

        for i:= 1 to c do s[i]:= t[i-1];

        s[0]:= char(c);

        ParseCommand(s, true, true);

        end

    else

        LuaParameterCountError('ParseCommand', 'string', lua_gettop(L));

    lc_parsecommand:= 0;

end;

function lc_showmission(L : Plua_State) : LongInt; Cdecl;

begin

    if lua_gettop(L) = 5 then

        begin

        ShowMission(lua_tostringA(L, 1), lua_tostringA(L, 2), lua_tostringA(L, 3), lua_tointeger(L, 4), lua_tointeger(L, 5));

        end

    else

        LuaParameterCountError('ShowMission', 'caption, subcaption, text, icon, time', lua_gettop(L));

    lc_showmission:= 0;

end;

function lc_hidemission(L : Plua_State) : LongInt; Cdecl;

begin

    L:= L; // avoid compiler hint

    HideMission;

    lc_hidemission:= 0;

end;

function lc_enablegameflags(L : Plua_State) : LongInt; Cdecl;

var i : integer;

begin

    if lua_gettop(L) = 0 then

        begin

        LuaParameterCountError('EnableGameFlags', '', lua_gettop(L));

        lua_pushnil(L);

        end

    else

        begin

            for i:= 1 to lua_gettop(L) do

                GameFlags := GameFlags or LongWord(lua_tointeger(L, i));

            ScriptSetInteger('GameFlags', GameFlags);

        end;

    lc_enablegameflags:= 0;

end;

function lc_disablegameflags(L : Plua_State) : LongInt; Cdecl;

var i : integer;

begin

    if lua_gettop(L) = 0 then

        begin

        LuaParameterCountError('DisableGameFlags', '', lua_gettop(L));

        lua_pushnil(L);

        end

    else

        begin

        for i:= 1 to lua_gettop(L) do

            GameFlags := GameFlags and (not LongWord(lua_tointeger(L, i)));

        ScriptSetInteger('GameFlags', GameFlags);

        end;

    lc_disablegameflags:= 0;

end;

function lc_cleargameflags(L : Plua_State) : LongInt; Cdecl;

begin

    if lua_gettop(L) <> 0 then

        begin

        LuaParameterCountError('ClearGameFlags', '', lua_gettop(L));

        lua_pushnil(L);

        end

    else

        begin

        GameFlags:= 0;

        ScriptSetInteger('GameFlags', GameFlags);

        end;

    lc_cleargameflags:= 0;

end;

function lc_getgameflag(L : Plua_State) : LongInt; Cdecl;

begin

    if lua_gettop(L) <> 1 then

        begin

        LuaParameterCountError('GetGameFlag', 'gameflag', lua_gettop(L));

        lua_pushnil(L);

        end

    else

        begin

        lua_pushboolean(L, (GameFlags and LongWord(lua_tointeger(L, 1)) <> 0));

        end;

    lc_getgameflag:= 1;

end;

function lc_addcaption(L : Plua_State) : LongInt; Cdecl;

begin

    if lua_gettop(L) = 1 then

        AddCaption(lua_tostringA(L, 1), cWhiteColor, capgrpMessage)

    else if lua_gettop(L) = 3 then

        begin

        AddCaption(lua_tostringA(L, 1), lua_tointeger(L, 2) shr 8, TCapGroup(lua_tointeger(L, 3)));

        end

    else

        LuaParameterCountError('AddCaption', 'text[, color, captiongroup]', lua_gettop(L));

    lc_addcaption:= 0;

end;

function lc_campaignlock(L : Plua_State) : LongInt; Cdecl;

begin

    if lua_gettop(L) = 1 then

        begin

        // to be done

        end

    else

        LuaParameterCountError('CampaignLock', 'TODO', lua_gettop(L));

    lc_campaignlock:= 0;

end;

function lc_campaignunlock(L : Plua_State) : LongInt; Cdecl;

begin

    if lua_gettop(L) = 1 then

        begin

        // to be done

        end

    else

        LuaParameterCountError('CampaignUnlock', 'TODO', lua_gettop(L));

    lc_campaignunlock:= 0;

end;

function lc_spawnfakehealthcrate(L: Plua_State) : LongInt; Cdecl;

var gear: PGear;

begin

    if lua_gettop(L) <> 4 then

        begin

        LuaParameterCountError('SpawnFakeHealthCrate', 'x, y, explode, poison', lua_gettop(L));

        lua_pushnil(L);

        end

    else

        begin

        gear := SpawnFakeCrateAt(lua_tointeger(L, 1), lua_tointeger(L, 2),

        HealthCrate, lua_toboolean(L, 3), lua_toboolean(L, 4));

        lua_pushinteger(L, gear^.uid);

        end;

    lc_spawnfakehealthcrate := 1;

end;

function lc_spawnfakeammocrate(L: PLua_State): LongInt; Cdecl;

var gear: PGear;

begin

    if lua_gettop(L) <> 4 then

        begin

        LuaParameterCountError('SpawnFakeAmmoCrate', 'x, y, explode, poison', lua_gettop(L));

        lua_pushnil(L);

        end

    else

        begin

        gear := SpawnFakeCrateAt(lua_tointeger(L, 1), lua_tointeger(L, 2),

        AmmoCrate, lua_toboolean(L, 3), lua_toboolean(L, 4));

        lua_pushinteger(L, gear^.uid);

        end;

    lc_spawnfakeammocrate := 1;

end;

function lc_spawnfakeutilitycrate(L: PLua_State): LongInt; Cdecl;

var gear: PGear;

begin

    if lua_gettop(L) <> 4 then

        begin

        LuaParameterCountError('SpawnFakeUtilityCrate', 'x, y, explode, poison', lua_gettop(L));

        lua_pushnil(L);

        end

    else

        begin

        gear := SpawnFakeCrateAt(lua_tointeger(L, 1), lua_tointeger(L, 2),

        UtilityCrate, lua_toboolean(L, 3), lua_toboolean(L, 4));

        lua_pushinteger(L, gear^.uid);

        end;

    lc_spawnfakeutilitycrate := 1;

end;

function lc_spawnhealthcrate(L: Plua_State) : LongInt; Cdecl;

var gear: PGear;

var health: LongInt;

begin

    if (lua_gettop(L) < 2) or (lua_gettop(L) > 3) then

        begin

        LuaParameterCountError('SpawnHealthCrate', 'x, y[, health]', lua_gettop(L));

        lua_pushnil(L);

        end

    else

        begin

        if lua_gettop(L) = 3 then

            health:= lua_tointeger(L, 3)

        else

            health:= cHealthCaseAmount;

        gear := SpawnCustomCrateAt(lua_tointeger(L, 1), lua_tointeger(L, 2), HealthCrate, health, 0);

        if gear <> nil then

            lua_pushinteger(L, gear^.uid)

        else

            lua_pushnil(L);

        end;

    lc_spawnhealthcrate := 1;

end;

function lc_spawnammocrate(L: PLua_State): LongInt; Cdecl;

var gear: PGear;

begin

    if (lua_gettop(L) <> 3) and (lua_gettop(L) <> 4) then

        begin

        LuaParameterCountError('SpawnAmmoCrate', 'x, y, content[, amount]', lua_gettop(L));

        lua_pushnil(L);

        end

    else

        begin

        if (lua_gettop(L) = 3) then

             gear := SpawnCustomCrateAt(lua_tointeger(L, 1), lua_tointeger(L, 2), AmmoCrate, lua_tointeger(L, 3), 0)

        else gear := SpawnCustomCrateAt(lua_tointeger(L, 1), lua_tointeger(L, 2), AmmoCrate, lua_tointeger(L, 3), lua_tointeger(L, 4));

        if gear <> nil then

            lua_pushinteger(L, gear^.uid)

        else

            lua_pushnil(L);

        end;

    lc_spawnammocrate := 1;

end;

function lc_spawnutilitycrate(L: PLua_State): LongInt; Cdecl;

var gear: PGear;

begin

    if (lua_gettop(L) <> 3) and (lua_gettop(L) <> 4) then

        begin

        LuaParameterCountError('SpawnUtilityCrate', 'x, y, content[, amount]', lua_gettop(L));

        lua_pushnil(L);

        end

    else

        begin

        if (lua_gettop(L) = 3) then

             gear := SpawnCustomCrateAt(lua_tointeger(L, 1), lua_tointeger(L, 2), UtilityCrate, lua_tointeger(L, 3), 0)

        else gear := SpawnCustomCrateAt(lua_tointeger(L, 1), lua_tointeger(L, 2), UtilityCrate, lua_tointeger(L, 3), lua_tointeger(L, 4));

        if gear <> nil then

            lua_pushinteger(L, gear^.uid)

        else

            lua_pushnil(L);

       end;

    lc_spawnutilitycrate := 1;

end;

function lc_addgear(L : Plua_State) : LongInt; Cdecl;

var gear : PGear;

    x, y, s, t: LongInt;

    dx, dy: hwFloat;

    gt: TGearType;

begin

    if lua_gettop(L) <> 7 then

        begin

        LuaParameterCountError('AddGear', 'x, y, gearType, state, dx, dy, timer', lua_gettop(L));

        lua_pushnil(L); // return value on stack (nil)

        end

    else

        begin

        x:= lua_tointeger(L, 1);

        y:= lua_tointeger(L, 2);

        gt:= TGearType(lua_tointeger(L, 3));

        s:= lua_tointeger(L, 4);

        dx:= int2hwFloat(lua_tointeger(L, 5)) / 1000000;

        dy:= int2hwFloat(lua_tointeger(L, 6)) / 1000000;

        t:= lua_tointeger(L, 7);

        gear:= AddGear(x, y, gt, s, dx, dy, t);

        lastGearByUID:= gear;

        lua_pushinteger(L, gear^.uid)

        end;