(*

 * Hedgewars, a free turn based strategy game

 * Copyright (c) 2004-2014 Andrey Korotaev <unC0Rr@gmail.com>

 *

 * This program is free software; you can redistribute it and/or modify

 * it under the terms of the GNU General Public License as published by

 * the Free Software Foundation; version 2 of the License

 *

 * This program is distributed in the hope that it will be useful,

 * but WITHOUT ANY WARRANTY; without even the implied warranty of

 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

 * GNU General Public License for more details.

 *

 * You should have received a copy of the GNU General Public License

 * along with this program; if not, write to the Free Software

 * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA

 *)

{$INCLUDE "options.inc"}

unit uGearsUtils;

interface

uses uTypes, uFloat;

procedure doMakeExplosion(X, Y, Radius: LongInt; AttackingHog: PHedgehog; Mask: Longword); inline;

procedure doMakeExplosion(X, Y, Radius: LongInt; AttackingHog: PHedgehog; Mask: Longword; const Tint: LongWord);

function  ModifyDamage(dmg: Longword; Gear: PGear): Longword;

procedure ApplyDamage(Gear: PGear; AttackerHog: PHedgehog; Damage: Longword; Source: TDamageSource);

procedure spawnHealthTagForHH(HHGear: PGear; dmg: Longword);

procedure HHHurt(Hedgehog: PHedgehog; Source: TDamageSource);

procedure CheckHHDamage(Gear: PGear);

procedure CalcRotationDirAngle(Gear: PGear);

procedure ResurrectHedgehog(var gear: PGear);

procedure FindPlace(var Gear: PGear; withFall: boolean; Left, Right: LongInt); inline;

procedure FindPlace(var Gear: PGear; withFall: boolean; Left, Right: LongInt; skipProximity: boolean);

function  CheckGearNear(Gear: PGear; Kind: TGearType; rX, rY: LongInt): PGear;

function  CheckGearDrowning(var Gear: PGear): boolean;

procedure CheckCollision(Gear: PGear); inline;

procedure CheckCollisionWithLand(Gear: PGear); inline;

procedure AmmoShove(Ammo: PGear; Damage, Power: LongInt);

function  GearsNear(X, Y: hwFloat; Kind: TGearType; r: LongInt): PGearArrayS;

procedure SpawnBoxOfSmth;

procedure ShotgunShot(Gear: PGear);

procedure SetAllToActive;

procedure SetAllHHToActive(Ice: boolean);

procedure SetAllHHToActive(); inline;

function  GetAmmo(Hedgehog: PHedgehog): TAmmoType;

function  GetUtility(Hedgehog: PHedgehog): TAmmoType;

function WorldWrap(var Gear: PGear): boolean;

function MakeHedgehogsStep(Gear: PGear) : boolean;

var doStepHandlers: array[TGearType] of TGearStepProcedure;

implementation

uses uSound, uCollisions, uUtils, uConsts, uVisualGears, uAIMisc,

    uVariables, uLandGraphics, uScript, uStats, uCaptions, uTeams, uStore,

    uLocale, uTextures, uRenderUtils, uRandom, SDLh, uDebug,

    uGearsList, Math, uVisualGearsList, uGearsHandlersMess,

    uGearsHedgehog;

procedure doMakeExplosion(X, Y, Radius: LongInt; AttackingHog: PHedgehog; Mask: Longword); inline;

begin

    doMakeExplosion(X, Y, Radius, AttackingHog, Mask, $FFFFFFFF);

end;

procedure doMakeExplosion(X, Y, Radius: LongInt; AttackingHog: PHedgehog; Mask: Longword; const Tint: LongWord);

var Gear: PGear;

    dmg, dmgBase: LongInt;

    fX, fY, tdX, tdY: hwFloat;

    vg: PVisualGear;

    i, cnt: LongInt;

begin

if Radius > 4 then AddFileLog('Explosion: at (' + inttostr(x) + ',' + inttostr(y) + ')');

if Radius > 25 then KickFlakes(Radius, X, Y);

if ((Mask and EXPLNoGfx) = 0) then

    begin

    vg:= nil;

    if Radius > 50 then vg:= AddVisualGear(X, Y, vgtBigExplosion)

    else if Radius > 10 then vg:= AddVisualGear(X, Y, vgtExplosion);

    if vg <> nil then

        vg^.Tint:= Tint;

    end;

if (Mask and EXPLAutoSound) <> 0 then PlaySound(sndExplosion);

(*if (Mask and EXPLAllDamageInRadius) = 0 then

    dmgRadius:= Radius shl 1

else

    dmgRadius:= Radius;

dmgBase:= dmgRadius + cHHRadius div 2;*)

dmgBase:= Radius shl 1 + cHHRadius div 2;

fX:= int2hwFloat(X);

fY:= int2hwFloat(Y);

Gear:= GearsList;

while Gear <> nil do

    begin

    dmg:= 0;

    //dmg:= dmgRadius  + cHHRadius div 2 - hwRound(Distance(Gear^.X - int2hwFloat(X), Gear^.Y - int2hwFloat(Y)));

    //if (dmg > 1) and

    if (Gear^.State and gstNoDamage) = 0 then

        begin

        case Gear^.Kind of

            gtHedgehog,

                gtMine,

                gtBall,

                gtMelonPiece,

                gtGrenade,

                gtClusterBomb,

            //    gtCluster, too game breaking I think

                gtSMine,

                gtCase,

                gtTarget,

                gtFlame,

                gtKnife,

                gtExplosives: begin //,

                //gtStructure: begin

// Run the calcs only once we know we have a type that will need damage

                        tdX:= Gear^.X-fX;

                        tdY:= Gear^.Y-fY;

                        if LongInt(tdX.Round + tdY.Round + 2) < dmgBase then

                            dmg:= dmgBase - hwRound(Distance(tdX, tdY));

                        if dmg > 1 then

                            begin

                            dmg:= ModifyDamage(min(dmg div 2, Radius), Gear);

                            //AddFileLog('Damage: ' + inttostr(dmg));

                            if (Mask and EXPLNoDamage) = 0 then

                                begin

                                if (Gear^.Kind <> gtHedgehog) or (Gear^.Hedgehog^.Effects[heInvulnerable] = 0) then

                                    ApplyDamage(Gear, AttackingHog, dmg, dsExplosion)

                                else

                                    Gear^.State:= Gear^.State or gstWinner;

                                end;

                            if ((Mask and EXPLDoNotTouchAny) = 0) and (((Mask and EXPLDoNotTouchHH) = 0) or (Gear^.Kind <> gtHedgehog)) then

                                begin

                                DeleteCI(Gear);

                                Gear^.dX:= Gear^.dX + SignAs(_0_005 * dmg + cHHKick, tdX)/(Gear^.Density/_3);

                                Gear^.dY:= Gear^.dY + SignAs(_0_005 * dmg + cHHKick, tdY)/(Gear^.Density/_3);

                                Gear^.State:= (Gear^.State or gstMoving) and (not gstLoser);

                                if Gear^.Kind = gtKnife then Gear^.State:= Gear^.State and (not gstCollision);

                                if (Gear^.Kind = gtHedgehog) and (Gear^.Hedgehog^.Effects[heInvulnerable] = 0) then

                                    Gear^.State:= (Gear^.State or gstMoving) and (not gstWinner);

                                Gear^.Active:= true;

                                if Gear^.Kind <> gtFlame then FollowGear:= Gear

                                end;

                            if ((Mask and EXPLPoisoned) <> 0) and (Gear^.Kind = gtHedgehog) and (Gear^.Hedgehog^.Effects[heInvulnerable] = 0) and (Gear^.State and gstHHDeath = 0) then

                                Gear^.Hedgehog^.Effects[hePoisoned] := 5;

                            end;

                        end;

                gtGrave: if Mask and EXPLDoNotTouchAny = 0 then

// Run the calcs only once we know we have a type that will need damage

                            begin

                            tdX:= Gear^.X-fX;

                            tdY:= Gear^.Y-fY;

                            if LongInt(tdX.Round + tdY.Round + 2) < dmgBase then

                                dmg:= dmgBase - hwRound(Distance(tdX, tdY));

                            if dmg > 1 then

                                begin

                                dmg:= ModifyDamage(min(dmg div 2, Radius), Gear);

                                Gear^.dY:= - _0_004 * dmg;

                                Gear^.Active:= true

                                end

                            end;

            end;

        end;

    Gear:= Gear^.NextGear

    end;

if (Mask and EXPLDontDraw) = 0 then

    if (GameFlags and gfSolidLand) = 0 then

        begin

        cnt:= DrawExplosion(X, Y, Radius) div 1608; // approx 2 16x16 circles to erase per chunk

        if (cnt > 0) and (SpritesData[sprChunk].Texture <> nil) then

            for i:= 0 to cnt do

                AddVisualGear(X, Y, vgtChunk)

        end;

uAIMisc.AwareOfExplosion(0, 0, 0)

end;

function ModifyDamage(dmg: Longword; Gear: PGear): Longword;

var i: hwFloat;

begin

(* Invulnerability cannot be placed in here due to still needing kicks

   Not without a new damage machine.

   King check should be in here instead of ApplyDamage since Tiy wants them kicked less

*)

i:= _1;

if (CurrentHedgehog <> nil) and CurrentHedgehog^.King then

    i:= _1_5;

if (Gear^.Kind = gtHedgehog) and (Gear^.Hedgehog <> nil) and

   (Gear^.Hedgehog^.King or (Gear^.Hedgehog^.Effects[heFrozen] > 0)) then

    ModifyDamage:= hwRound(cDamageModifier * dmg * i * cDamagePercent * _0_5 * _0_01)

else

    ModifyDamage:= hwRound(cDamageModifier * dmg * i * cDamagePercent * _0_01)

end;

procedure ApplyDamage(Gear: PGear; AttackerHog: PHedgehog; Damage: Longword; Source: TDamageSource);

var s: shortstring;

    vampDmg, tmpDmg, i: Longword;

    vg: PVisualGear;

begin

    if Damage = 0 then

        exit; // nothing to apply

    if (Gear^.Kind = gtHedgehog) then

        begin

        Gear^.LastDamage := AttackerHog;

        Gear^.Hedgehog^.Team^.Clan^.Flawless:= false;

        HHHurt(Gear^.Hedgehog, Source);

        AddDamageTag(hwRound(Gear^.X), hwRound(Gear^.Y), Damage, Gear^.Hedgehog^.Team^.Clan^.Color);

        tmpDmg:= min(Damage, max(0,Gear^.Health-Gear^.Damage));

        if (Gear <> CurrentHedgehog^.Gear) and (CurrentHedgehog^.Gear <> nil) and (tmpDmg >= 1) then

            begin

            if cVampiric then

                begin

                vampDmg:= hwRound(int2hwFloat(tmpDmg)*_0_8);

                if vampDmg >= 1 then

                    begin

                    // was considering pulsing on attack, Tiy thinks it should be permanent while in play

                    //CurrentHedgehog^.Gear^.State:= CurrentHedgehog^.Gear^.State or gstVampiric;

                    inc(CurrentHedgehog^.Gear^.Health,vampDmg);

                    str(vampDmg, s);

                    s:= '+' + s;

                    AddCaption(ansistring(s), CurrentHedgehog^.Team^.Clan^.Color, capgrpAmmoinfo);

                    RenderHealth(CurrentHedgehog^);

                    RecountTeamHealth(CurrentHedgehog^.Team);

                    i:= 0;

                    while i < vampDmg do

                        begin

                        vg:= AddVisualGear(hwRound(CurrentHedgehog^.Gear^.X), hwRound(CurrentHedgehog^.Gear^.Y), vgtStraightShot);

                        if vg <> nil then

                            with vg^ do

                                begin

                                Tint:= $FF0000FF;

                                State:= ord(sprHealth)

                                end;

                        inc(i, 5);

                        end;

                    end

                end;

        if (GameFlags and gfKarma <> 0) and (GameFlags and gfInvulnerable = 0) and

           (CurrentHedgehog^.Effects[heInvulnerable] = 0) then

            begin // this cannot just use Damage or it interrupts shotgun and gets you called stupid

            inc(CurrentHedgehog^.Gear^.Karma, tmpDmg);

            CurrentHedgehog^.Gear^.LastDamage := CurrentHedgehog;

            spawnHealthTagForHH(CurrentHedgehog^.Gear, tmpDmg);

            end;

        uStats.HedgehogDamaged(Gear, AttackerHog, Damage, false);

        end;

    end else

    //else if Gear^.Kind <> gtStructure then // not gtHedgehog nor gtStructure

        Gear^.Hedgehog:= AttackerHog;

    inc(Gear^.Damage, Damage);

    ScriptCall('onGearDamage', Gear^.UID, Damage);

end;

procedure spawnHealthTagForHH(HHGear: PGear; dmg: Longword);

var tag: PVisualGear;

begin

tag:= AddVisualGear(hwRound(HHGear^.X), hwRound(HHGear^.Y), vgtHealthTag, dmg);

if (tag <> nil) then

    tag^.Hedgehog:= HHGear^.Hedgehog; // the tag needs the tag to determine the text color

AllInactive:= false;

HHGear^.Active:= true;

end;

procedure HHHurt(Hedgehog: PHedgehog; Source: TDamageSource);

begin

if Hedgehog^.Effects[heFrozen] <> 0 then exit;

if (Source = dsFall) or (Source = dsExplosion) then

    case random(3) of

        0: PlaySoundV(sndOoff1, Hedgehog^.Team^.voicepack);

        1: PlaySoundV(sndOoff2, Hedgehog^.Team^.voicepack);

        2: PlaySoundV(sndOoff3, Hedgehog^.Team^.voicepack);

    end

else if (Source = dsPoison) then

    case random(2) of

        0: PlaySoundV(sndPoisonCough, Hedgehog^.Team^.voicepack);

        1: PlaySoundV(sndPoisonMoan, Hedgehog^.Team^.voicepack);

    end

else

    case random(4) of

        0: PlaySoundV(sndOw1, Hedgehog^.Team^.voicepack);

        1: PlaySoundV(sndOw2, Hedgehog^.Team^.voicepack);

        2: PlaySoundV(sndOw3, Hedgehog^.Team^.voicepack);

        3: PlaySoundV(sndOw4, Hedgehog^.Team^.voicepack);

    end

end;

procedure CheckHHDamage(Gear: PGear);

var

    dmg: LongInt;

    i: LongWord;

    particle: PVisualGear;

begin

if _0_4 < Gear^.dY then

    begin

    dmg := ModifyDamage(1 + hwRound((Gear^.dY - _0_4) * 70), Gear);

    if Gear^.Hedgehog^.Effects[heFrozen] = 0 then

         PlaySound(sndBump)

    else PlaySound(sndFrozenHogImpact);

    if dmg < 1 then

        exit;

    for i:= min(12, 3 + dmg div 10) downto 0 do

        begin

        particle := AddVisualGear(hwRound(Gear^.X) - 5 + Random(10), hwRound(Gear^.Y) + 12, vgtDust);

        if particle <> nil then

            particle^.dX := particle^.dX + (Gear^.dX.QWordValue / 21474836480);

        end;

    if ((Gear^.Hedgehog^.Effects[heInvulnerable] <> 0)) then

        exit;

    //if _0_6 < Gear^.dY then

    //    PlaySound(sndOw4, Gear^.Hedgehog^.Team^.voicepack)

    //else

    //    PlaySound(sndOw1, Gear^.Hedgehog^.Team^.voicepack);

    if Gear^.LastDamage <> nil then

        ApplyDamage(Gear, Gear^.LastDamage, dmg, dsFall)

    else

        ApplyDamage(Gear, CurrentHedgehog, dmg, dsFall);

    end

end;

procedure CalcRotationDirAngle(Gear: PGear);

var

    dAngle: real;

begin

    // Frac/Round to be kind to JS as of 2012-08-27 where there is yet no int64/uint64

    //dAngle := (Gear^.dX.QWordValue + Gear^.dY.QWordValue) / $80000000;

    dAngle := (Gear^.dX.Round + Gear^.dY.Round) / 2 + (Gear^.dX.Frac/$100000000+Gear^.dY.Frac/$100000000);

    if not Gear^.dX.isNegative then

        Gear^.DirAngle := Gear^.DirAngle + dAngle

    else

        Gear^.DirAngle := Gear^.DirAngle - dAngle;

    if Gear^.DirAngle < 0 then

        Gear^.DirAngle := Gear^.DirAngle + 360

    else if 360 < Gear^.DirAngle then

        Gear^.DirAngle := Gear^.DirAngle - 360

end;

procedure DrownGear(Gear: PGear);

begin

Gear^.doStep := @doStepDrowningGear;

Gear^.Timer := 5000; // how long game should wait

end;

function CheckGearDrowning(var Gear: PGear): boolean;

var

    skipSpeed, skipAngle, skipDecay, hwTmp: hwFloat;

    i, maxDrops, X, Y, dist2Water: LongInt;

    vdX, vdY, tmp: real;

    particle, splash: PVisualGear;

    isSubmersible, isImpactH, isImpactRight, isLeaving: boolean;

    s: ansistring;

begin

    // probably needs tweaking. might need to be in a case statement based upon gear type

    X:= hwRound(Gear^.X);

    Y:= hwRound(Gear^.Y);

    dist2Water:= cWaterLine - (Y + Gear^.Radius);

    isImpactH:= false;

    if WorldEdge = weSea then

        begin

        i:= dist2Water;

        dist2Water:= min(dist2Water, min(X - Gear^.Radius - leftX, rightX - (X + Gear^.Radius)));

        isImpactH:= i <> dist2Water;

        end;

    if dist2Water < 0 then

        begin

        // invisible gears will just be deleted

        // unless they are generic fallers, then they will be "respawned"

        if Gear^.State and gstInvisible <> 0 then

            begin

            if Gear^.Kind = gtGenericFaller then

                begin

                Gear^.X:= int2hwFloat(GetRandom(rightX-leftX)+leftX);

                Gear^.Y:= int2hwFloat(GetRandom(LAND_HEIGHT-topY)+topY);

                Gear^.dX:= _90-(GetRandomf*_360);

                Gear^.dY:= _90-(GetRandomf*_360)

                end

            else DeleteGear(Gear);

            exit(true)

            end;

        isSubmersible:= ((Gear = CurrentHedgehog^.Gear) and (CurAmmoGear <> nil) and (CurAmmoGear^.State and gstSubmersible <> 0)) or (Gear^.State and gstSubmersible <> 0);

        skipSpeed := _0_25;

        skipAngle := _1_9;

        skipDecay := _0_87;

        vdX:= abs(hwFloat2Float(Gear^.dX));

        vdY:= abs(hwFloat2Float(Gear^.dY));

        // skipping

        // check for -1 depth because if deeper, then it already had its chance of skipping

        if  (dist2Water = -1) and (hwSqr(Gear^.dX) + hwSqr(Gear^.dY) > skipSpeed)

        and ( ((not isImpactH) and (hwAbs(Gear^.dX) > skipAngle * hwAbs(Gear^.dY)))

          or (isImpactH and (hwAbs(Gear^.dY) > skipAngle * hwAbs(Gear^.dX))) ) then

            begin

            // if skipping we move the gear out of water

            if isImpactH then

                begin

                Gear^.dX.isNegative := (not Gear^.dX.isNegative);

                Gear^.X:= Gear^.X + Gear^.dX;

                end

            else

                begin

                Gear^.dY.isNegative := (not Gear^.dY.isNegative);

                Gear^.Y:= Gear^.Y + Gear^.dY;

                end;

            Gear^.dY := Gear^.dY * skipDecay;

            Gear^.dX := Gear^.dX * skipDecay;

            CheckGearDrowning := false;

            PlaySound(sndSkip)

            end

        else // not skipping

            begin

            if not isSubmersible then

                begin

                CheckGearDrowning := true;

                Gear^.State := gstDrowning;

                Gear^.RenderTimer := false;

                if (Gear^.Kind <> gtSniperRifleShot) and (Gear^.Kind <> gtShotgunShot)

                and (Gear^.Kind <> gtDEagleShot) and (Gear^.Kind <> gtSineGunShot) then

                    if Gear^.Kind = gtHedgehog then

                        begin

                        if Gear^.Hedgehog^.Effects[heResurrectable] <> 0 then

                            begin

                            // Gear could become nil after this, just exit to skip splashes

                            ResurrectHedgehog(Gear);

                            exit(true)

                            end

                        else

                            begin

                            DrownGear(Gear);

                            Gear^.State := Gear^.State and (not gstHHDriven);

                            s:= ansistring(Gear^.Hedgehog^.Name);

                            AddCaption(FormatA(GetEventString(eidDrowned), s), cWhiteColor, capgrpMessage);

                            end

                        end

                    else

                        DrownGear(Gear);

                    if Gear^.Kind = gtFlake then

                        exit(true); // skip splashes

                end

            // drown submersible grears if far below map

            else if (Y > cWaterLine + cVisibleWater*4) and

                    ((Gear <> CurrentHedgehog^.Gear) or (CurAmmoGear = nil) or (CurAmmoGear^.State and gstSubmersible = 0)) then

                DrownGear(Gear);

            isLeaving:= (isSubmersible and (dist2Water = -2 * Gear^.Radius) and (Gear = CurAmmoGear) and (CurAmmoGear^.Pos = 0)

            and (((not isImpactH) and CurAmmoGear^.dY.isNegative) or (isImpactH and (isImpactRight = CurAmmoGear^.dX.isNegative))));

            // splash sound

            if ((not isSubmersible) and (dist2Water = -1))

            or isLeaving then

                begin

                // adjust water impact sound on gear speed and density

                if isImpactH then

                    hwTmp:= hwAbs(Gear^.Density * Gear^.dX)

                else

                    hwTmp:= hwAbs(Gear^.Density * Gear^.dY);