(*

* Hedgewars, a free turn based strategy game

* Copyright (c) 2004-2008 Andrey Korotaev <unC0Rr@gmail.com>

*

* This program is free software; you can redistribute it and/or modify

* it under the terms of the GNU General Public License as published by

* the Free Software Foundation; version 2 of the License

*

* This program is distributed in the hope that it will be useful,

* but WITHOUT ANY WARRANTY; without even the implied warranty of

* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

* GNU General Public License for more details.

*

* You should have received a copy of the GNU General Public License

* along with this program; if not, write to the Free Software

* Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA

*)

{$INCLUDE "options.inc"}

unit uMisc;

interface

uses    SDLh, uConsts, uFloat, GLunit, Math;

var

/////// init flags ///////

    cScreenWidth    : LongInt     = 1024;

    cScreenHeight   : LongInt     = 768;

    cBits           : LongInt     = 32;

    //ipcPort is in uIO

    cFullScreen     : boolean     = false;

    isSoundEnabled  : boolean     = true;

    isMusicEnabled  : boolean     = false;

    cLocaleFName    : shortstring = 'en.txt';

    cInitVolume     : LongInt     = 100;

    cTimerInterval  : LongInt     = 8;

    PathPrefix      : shortstring = './';

    cShowFPS        : boolean     = false;

    cAltDamage      : boolean     = true;

    cReducedQuality : LongInt     = rqNone;

    //userNick is in uChat

    recordFileName  : shortstring = '';

    cReadyDelay     : Longword    = 0;

    cLogfileBase    : shortstring = 'debug';

//////////////////////////

    isCursorVisible : boolean;

    isTerminated    : boolean;

    isInLag         : boolean;

    isPaused        : boolean;

    isSEBackup      : boolean;

    isInMultiShoot  : boolean;

    isSpeed         : boolean;

    isFirstFrame    : boolean;

    fastUntilLag    : boolean;

    GameState       : TGameState;

    GameType        : TGameType;

    GameFlags       : Longword;

    TrainingFlags   : Longword;

    TurnTimeLeft    : Longword;

    ReadyTimeLeft   : Longword;

    cSuddenDTurns   : LongInt;

    cDamagePercent  : LongInt;

    cMineDudPercent : LongWord;

    cTemplateFilter : LongInt;

    cMapGen         : LongInt;

    cMazeSize       : LongInt;

    cHedgehogTurnTime: Longword;

    cMinesTime       : LongInt;

    cMaxAIThinkTime  : Longword;

    cCloudsNumber    : LongInt;

    cTagsMask        : byte;

    zoom             : GLfloat;

    ZoomValue        : GLfloat;

    cWaterLine       : LongInt;

    cGearScrEdgesDist: LongInt;

    GameTicks   : LongWord;

    TrainingTimeInc : Longword;

    TrainingTimeInD : Longword;

    TrainingTimeInM : Longword;

    TrainingTimeMax : Longword;

    TimeTrialStartTime: Longword;

    TimeTrialStopTime : Longword;

    // originally from uConsts

    Pathz: array[TPathType] of shortstring;

    CountTexz: array[1..Pred(AMMO_INFINITE)] of PTexture;

    LAND_WIDTH       : LongInt;

    LAND_HEIGHT      : LongInt;

    LAND_WIDTH_MASK  : LongWord;

    LAND_HEIGHT_MASK : LongWord;

    cMaxCaptions     : LongInt;

    cLeftScreenBorder     : LongInt;

    cRightScreenBorder    : LongInt;

    cScreenSpace          : LongInt;

    cCaseFactor     : Longword;

    cLandMines      : Longword;

    cExplosives     : Longword;

    cSeed           : shortstring;

    cVolumeDelta    : LongInt;

    cHasFocus       : boolean;

    cInactDelay     : Longword;

    bBetweenTurns   : boolean;

    cHealthDecrease : LongWord;

    bWaterRising    : Boolean;

    ShowCrosshair   : boolean;

    CursorMovementX : LongInt;

    CursorMovementY : LongInt;

    cDrownSpeed     : hwFloat;

    cDrownSpeedf    : float;

    cMaxWindSpeed   : hwFloat;

    cWindSpeed      : hwFloat;

    cWindSpeedf     : float;

    cGravity        : hwFloat;

    cGravityf       : float;

    cDamageModifier : hwFloat;

    cLaserSighting  : boolean;

    cVampiric       : boolean;

    cArtillery      : boolean;

    WeaponTooltipTex : PTexture;

    flagMakeCapture : boolean;

    InitStepsFlags  : Longword;

    RealTicks       : Longword;

    AttackBar       : LongInt;

    WaterColorArray : array[0..3] of HwColor4f;

    CursorPoint     : TPoint;

    TargetPoint     : TPoint;

    TextureList     : PTexture;

    ScreenFade      : TScreenFade;

    ScreenFadeValue : LongInt;

    ScreenFadeSpeed : LongInt;

{$IFDEF SDL13}

    SDLwindow       : PSDL_Window;

{$ENDIF}

procedure initModule;

procedure freeModule;

procedure SplitBySpace(var a, b: shortstring);

procedure SplitByChar(var a, b: ansistring; c: char);

function  EnumToStr(const en : TGearType) : shortstring; overload;

function  EnumToStr(const en : TSound) : shortstring; overload;

function  EnumToStr(const en : TAmmoType) : shortstring; overload;

function  EnumToStr(const en : THogEffect) : shortstring; overload;

procedure movecursor(dx, dy: LongInt);

function  hwSign(r: hwFloat): LongInt; inline;

function  Min(a, b: LongInt): LongInt; inline;

function  Max(a, b: LongInt): LongInt; inline;

procedure OutError(Msg: shortstring; isFatalError: boolean);

procedure TryDo(Assert: boolean; Msg: shortstring; isFatal: boolean); inline;

procedure SDLTry(Assert: boolean; isFatal: boolean);

function  IntToStr(n: LongInt): shortstring;

function  FloatToStr(n: hwFloat): shortstring;

function  DxDy2Angle(const _dY, _dX: hwFloat): GLfloat;

function  DxDy2Angle32(const _dY, _dX: hwFloat): LongInt;

function  DxDy2AttackAngle(const _dY, _dX: hwFloat): LongInt;

(*

procedure AdjustColor(var Color: Longword);

procedure SetKB(n: Longword);

*)

procedure SendKB;

procedure SetLittle(var r: hwFloat);

procedure SendStat(sit: TStatInfoType; s: shortstring);

function  Str2PChar(const s: shortstring): PChar;

function  NewTexture(width, height: Longword; buf: Pointer): PTexture;

function  Surface2Tex(surf: PSDL_Surface; enableClamp: boolean): PTexture;

procedure FreeTexture(tex: PTexture);

function  toPowerOf2(i: Longword): Longword; inline;

function  DecodeBase64(s: shortstring): shortstring;

function  doSurfaceConversion(tmpsurf: PSDL_Surface): PSDL_Surface;

function  endian(independent: LongWord): LongWord; inline;

{$IFDEF DEBUGFILE}

procedure AddFileLog(s: shortstring);

(* function  RectToStr(Rect: TSDL_Rect): shortstring; *)

{$ENDIF}

procedure MakeScreenshot(filename: shortstring);

implementation

uses uConsole, uStore, uIO, uSound, typinfo, sysutils, uMobile;

var KBnum: Longword;

{$IFDEF DEBUGFILE}

    f: textfile;

{$ENDIF}

// should this include "strtolower()" for the split string?

procedure SplitBySpace(var a, b: shortstring);

var i, t: LongInt;

begin

i:= Pos(' ', a);

if i > 0 then

    begin

    for t:= 1 to Pred(i) do

        if (a[t] >= 'A')and(a[t] <= 'Z') then Inc(a[t], 32);

    b:= copy(a, i + 1, Length(a) - i);

    byte(a[0]):= Pred(i)

    end else b:= '';

end;

procedure SplitByChar(var a, b: ansistring; c: char);

var i: LongInt;

begin

i:= Pos(c, a);

if i > 0 then

    begin

    b:= copy(a, i + 1, Length(a) - i);

    setlength(a, Pred(i));

    end else b:= '';

end;

function EnumToStr(const en : TGearType) : shortstring; overload;

begin

EnumToStr:= GetEnumName(TypeInfo(TGearType), ord(en))

end;

function EnumToStr(const en : TSound) : shortstring; overload;

begin

EnumToStr:= GetEnumName(TypeInfo(TSound), ord(en))

end;

function EnumToStr(const en : TAmmoType) : shortstring; overload;

begin

EnumToStr:= GetEnumName(TypeInfo(TAmmoType), ord(en))

end;

function EnumToStr(const en: THogEffect) : shortstring; overload;

begin

    EnumToStr := GetEnumName(TypeInfo(THogEffect), ord(en))

end;

procedure movecursor(dx, dy: LongInt);

var x, y: LongInt;

begin

if (dx = 0) and (dy = 0) then exit;

SDL_GetMouseState(@x, @y);

Inc(x, dx);

Inc(y, dy);

SDL_WarpMouse(x, y);

end;

function hwSign(r: hwFloat): LongInt;

begin

// yes, we have negative zero for a reason

if r.isNegative then hwSign:= -1 else hwSign:= 1

end;

function Min(a, b: LongInt): LongInt;

begin

if a < b then Min:= a else Min:= b

end;

function Max(a, b: LongInt): LongInt;

begin

if a > b then Max:= a else Max:= b

end;

procedure OutError(Msg: shortstring; isFatalError: boolean);

begin

// obsolete? written in WriteLnToConsole() anyway

// {$IFDEF DEBUGFILE}AddFileLog(Msg);{$ENDIF}

WriteLnToConsole(Msg);

if isFatalError then

    begin

    SendIPC('E' + GetLastConsoleLine);

    SDL_Quit;

    halt(1)

    end

end;

procedure TryDo(Assert: boolean; Msg: shortstring; isFatal: boolean);

begin

if not Assert then OutError(Msg, isFatal)

end;

procedure SDLTry(Assert: boolean; isFatal: boolean);

begin

if not Assert then OutError(SDL_GetError, isFatal)

end;

(*

procedure AdjustColor(var Color: Longword);

begin

Color:= SDL_MapRGB(PixelFormat, (Color shr 16) and $FF, (Color shr 8) and $FF, Color and $FF)

end;

procedure SetKB(n: Longword);

begin

KBnum:= n

end;

*)

function IntToStr(n: LongInt): shortstring;

begin

str(n, IntToStr)

end;

function FloatToStr(n: hwFloat): shortstring;

begin

FloatToStr:= cstr(n) + '_' + inttostr(Lo(n.QWordValue))

end;

procedure SetTextureParameters(enableClamp: Boolean);

begin

    if enableClamp and ((cReducedQuality and rqClampLess) = 0) then

    begin

        glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_WRAP_S, GL_CLAMP_TO_EDGE);

        glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_WRAP_T, GL_CLAMP_TO_EDGE)

    end;

    glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR);

    glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR)

end;

function DxDy2Angle(const _dY, _dX: hwFloat): GLfloat;

var dY, dX: Extended;

begin

dY:= _dY.QWordValue / $100000000;

if _dY.isNegative then dY:= - dY;

dX:= _dX.QWordValue / $100000000;

if _dX.isNegative then dX:= - dX;

DxDy2Angle:= arctan2(dY, dX) * 180 / pi

end;

function DxDy2Angle32(const _dY, _dX: hwFloat): LongInt;

const _16divPI: Extended = 16/pi;

var dY, dX: Extended;

begin

dY:= _dY.QWordValue / $100000000;

if _dY.isNegative then dY:= - dY;

dX:= _dX.QWordValue / $100000000;

if _dX.isNegative then dX:= - dX;

DxDy2Angle32:= trunc(arctan2(dY, dX) * _16divPI) and $1f

end;

function DxDy2AttackAngle(const _dY, _dX: hwFloat): LongInt;

const MaxAngleDivPI: Extended = cMaxAngle/pi;

var dY, dX: Extended;

begin

dY:= _dY.QWordValue / $100000000;

if _dY.isNegative then dY:= - dY;

dX:= _dX.QWordValue / $100000000;

if _dX.isNegative then dX:= - dX;

DxDy2AttackAngle:= trunc(arctan2(dY, dX) * MaxAngleDivPI)

end;

procedure SendKB;

var s: shortstring;

begin

if KBnum <> 0 then

begin

s:= 'K' + inttostr(KBnum);

SendIPCRaw(@s, Length(s) + 1)

end

end;

procedure SetLittle(var r: hwFloat);

begin

r:= SignAs(cLittle, r)

end;

procedure SendStat(sit: TStatInfoType; s: shortstring);

const stc: array [TStatInfoType] of char = 'rDkKHTPsSB';

var buf: shortstring;

begin

buf:= 'i' + stc[sit] + s;

SendIPCRaw(@buf[0], length(buf) + 1)

end;

function Str2PChar(const s: shortstring): PChar;

const CharArray: array[byte] of Char = '';

begin

CharArray:= s;

CharArray[Length(s)]:= #0;

Str2PChar:= @CharArray

end;

function isPowerOf2(i: Longword): boolean;

begin

if i = 0 then exit(true);

while (i and 1) = 0 do i:= i shr 1;

isPowerOf2:= (i = 1)

end;

function toPowerOf2(i: Longword): Longword;

begin

toPowerOf2:= 1;

while (toPowerOf2 < i) do toPowerOf2:= toPowerOf2 shl 1

end;

procedure ResetVertexArrays(texture: PTexture);

begin

with texture^ do

    begin

    vb[0].X:= 0;

    vb[0].Y:= 0;

    vb[1].X:= w;

    vb[1].Y:= 0;

    vb[2].X:= w;

    vb[2].Y:= h;

    vb[3].X:= 0;

    vb[3].Y:= h;

    tb[0].X:= 0;

    tb[0].Y:= 0;

    tb[1].X:= rx;

    tb[1].Y:= 0;

    tb[2].X:= rx;

    tb[2].Y:= ry;

    tb[3].X:= 0;

    tb[3].Y:= ry

    end;

end;

function NewTexture(width, height: Longword; buf: Pointer): PTexture;

begin

new(NewTexture);

NewTexture^.PrevTexture:= nil;

NewTexture^.NextTexture:= nil;

NewTexture^.Scale:= 1;

if TextureList <> nil then

    begin

    TextureList^.PrevTexture:= NewTexture;

    NewTexture^.NextTexture:= TextureList

    end;

TextureList:= NewTexture;

NewTexture^.w:= width;

NewTexture^.h:= height;

NewTexture^.rx:= 1.0;

NewTexture^.ry:= 1.0;

ResetVertexArrays(NewTexture);

glGenTextures(1, @NewTexture^.id);

glBindTexture(GL_TEXTURE_2D, NewTexture^.id);

glTexImage2D(GL_TEXTURE_2D, 0, GL_RGBA, width, height, 0, GL_RGBA, GL_UNSIGNED_BYTE, buf);

SetTextureParameters(true);

end;

function Surface2Tex(surf: PSDL_Surface; enableClamp: boolean): PTexture;

var tw, th, x, y: Longword;

    tmpp: pointer;

    fromP4, toP4: PLongWordArray;

begin

new(Surface2Tex);

Surface2Tex^.PrevTexture:= nil;

Surface2Tex^.NextTexture:= nil;

if TextureList <> nil then

    begin

    TextureList^.PrevTexture:= Surface2Tex;

    Surface2Tex^.NextTexture:= TextureList

    end;

TextureList:= Surface2Tex;

Surface2Tex^.w:= surf^.w;

Surface2Tex^.h:= surf^.h;

if (surf^.format^.BytesPerPixel <> 4) then