(*

 * Hedgewars, a free turn based strategy game

 * Copyright (c) 2004-2015 Andrey Korotaev <unC0Rr@gmail.com>

 *

 * This program is free software; you can redistribute it and/or modify

 * it under the terms of the GNU General Public License as published by

 * the Free Software Foundation; version 2 of the License

 *

 * This program is distributed in the hope that it will be useful,

 * but WITHOUT ANY WARRANTY; without even the implied warranty of

 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

 * GNU General Public License for more details.

 *

 * You should have received a copy of the GNU General Public License

 * along with this program; if not, write to the Free Software

 * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA

 *)

{$INCLUDE "options.inc"}

unit uGearsHedgehog;

interface

uses uTypes, uGearsHandlersMess;

procedure doStepHedgehog(Gear: PGear);

procedure AfterAttack;

procedure HedgehogStep(Gear: PGear);

procedure doStepHedgehogMoving(Gear: PGear);

procedure HedgehogChAngle(HHGear: PGear);

procedure PickUp(HH, Gear: PGear);

procedure AddPickup(HH: THedgehog; ammo: TAmmoType; cnt, X, Y: LongWord);

procedure CheckIce(Gear: PGear); inline;

procedure PlayTaunt(taunt: Longword);

function HHGetTimer(Gear: PGear): LongWord;

function HHGetTimerMsg(Gear: PGear): LongWord;

function HHGetBounciness(Gear: PGear): LongWord;

function HHGetBouncinessMsg(Gear: PGear): LongWord;

implementation

uses uConsts, uVariables, uFloat, uAmmos, uSound, uCaptions,

    uCommands, uLocale, uUtils, uStats, uIO, uScript,

    uGearsList, uCollisions, uRandom, uStore, uTeams,

    uGearsUtils, uVisualGearsList, uChat;

var GHStepTicks: LongWord = 0;

procedure AFKSkip;

var

    t: byte;

begin

    t:= 0;

    while (TeamsArray[t] <> CurrentTeam) do inc(t);

    AddChatString(#2 + FormatA(trmsg[sidAutoSkip], CurrentTeam^.TeamName));

    ParseCommand('/skip', true)

end;

// Shouldn't more of this ammo switching stuff be moved to uAmmos ?

function ChangeAmmo(HHGear: PGear): boolean;

var slot, i: Longword;

    ammoidx: LongInt;

    prevAmmo: TAmmoType;

begin

ChangeAmmo:= false;

slot:= HHGear^.MsgParam;

with HHGear^.Hedgehog^ do

    begin

    HHGear^.Message:= HHGear^.Message and (not gmSlot);

    prevAmmo:= CurAmmoType;

    ammoidx:= 0;

    if (((HHGear^.State and (gstAttacking or gstAttacked)) <> 0) and (GameFlags and gfInfAttack = 0))

    or ((HHGear^.State and gstHHDriven) = 0) then

        exit;

    ChangeAmmo:= true;

    while (ammoidx < cMaxSlotAmmoIndex) and (Ammo^[slot, ammoidx].AmmoType <> CurAmmoType) do

        inc(ammoidx);

    if (MultiShootAttacks > 0) then

        begin

        if (Effects[heArtillery] = 2) then

            Effects[heArtillery]:= 0;

        if (Ammoz[CurAmmoType].Ammo.Propz and ammoprop_NoRoundEnd) = 0 then

            begin

            MultiShootAttacks:= Ammoz[CurAmmoType].Ammo.NumPerTurn;

            AfterAttack

            end

        else OnUsedAmmo(HHGear^.Hedgehog^)

        end;

    MultiShootAttacks:= 0;

    HHGear^.Message:= HHGear^.Message and (not (gmLJump or gmHJump));

    if Ammoz[CurAmmoType].Slot = slot then

        begin

        i:= 0;

        repeat

        inc(ammoidx);

        if (ammoidx > cMaxSlotAmmoIndex) then

            begin

            inc(i);

            CurAmmoType:= amNothing;

            ammoidx:= -1;

            //TryDo(i < 2, 'Engine bug: no ammo in current slot', true)

            end;

        until (i = 1) or ((Ammo^[slot, ammoidx].Count > 0)

        and (Team^.Clan^.TurnNumber > Ammoz[Ammo^[slot, ammoidx].AmmoType].SkipTurns))

        end

    else

        begin

        i:= 0;

        // check whether there is ammo in slot

        while (i <= cMaxSlotAmmoIndex) and ((Ammo^[slot, i].Count = 0)

        or (Team^.Clan^.TurnNumber <= Ammoz[Ammo^[slot, i].AmmoType].SkipTurns))

            do inc(i);

        if i <= cMaxSlotAmmoIndex then

            ammoidx:= i

        else ammoidx:= -1

        end;

        if ammoidx >= 0 then

            CurAmmoType:= Ammo^[slot, ammoidx].AmmoType;

    // Try again in the next slot

    if (CurAmmoType = prevAmmo) and (slot < cMaxSlotIndex) then

        begin

        inc(slot);

        HHGear^.MsgParam:= slot;

        ChangeAmmo(HHGear)

        end

    end

end;

procedure HHSetWeapon(HHGear: PGear);

var t: LongInt;

    weap: TAmmoType;

    Hedgehog: PHedgehog;

    s: boolean;

    prevState, newState: LongWord;

begin

s:= false;

weap:= TAmmoType(HHGear^.MsgParam);

Hedgehog:= HHGear^.Hedgehog;

HHGear^.Message:= HHGear^.Message and (not gmWeapon);

// Special case: amNothing unselects weapon

if weap = amNothing then

    begin

    HHGear^.Hedgehog^.CurAmmoType:= amNothing;

    ApplyAmmoChanges(HHGear^.Hedgehog^);

    exit

    end;

if Hedgehog^.Team^.Clan^.TurnNumber <= Ammoz[weap].SkipTurns then

    exit; // weapon is not activated yet

HHGear^.MsgParam:= Ammoz[weap].Slot;

t:= cMaxSlotAmmoIndex;

prevState:= HHGear^.State;

newState:= prevState;

with Hedgehog^ do

    while (CurAmmoType <> weap) and (t >= 0) do

        begin

        s:= ChangeAmmo(HHGear);

        if HHGear^.State <> prevState then // so we can keep gstAttacked out of consideration when looping

            newState:= HHGear^.State;

        HHGear^.State:= prevState;

        dec(t)

        end;

HHGear^.State:= newState;

if s then

    ApplyAmmoChanges(HHGear^.Hedgehog^)

end;

procedure HHSetTimer(Gear: PGear);

var CurWeapon: PAmmo;

    color: LongWord;

begin

Gear^.Message:= Gear^.Message and (not gmTimer);

CurWeapon:= GetCurAmmoEntry(Gear^.Hedgehog^);

with Gear^.Hedgehog^ do

    if (((Gear^.State and gstAttacked) <> 0) and (GameFlags and gfInfAttack = 0))

    or ((Gear^.State and gstHHDriven) = 0) then

        exit;

    if ((Gear^.Message and gmPrecise) <> 0) and ((CurWeapon^.Propz and ammoprop_SetBounce) <> 0) then

        begin

        color:= Gear^.Hedgehog^.Team^.Clan^.Color;

        case Gear^.MsgParam of

            1: begin

               AddCaption(FormatA(trmsg[sidBounce], trmsg[sidBounce1]), color, capgrpAmmostate);

               end;

            2: begin

               AddCaption(FormatA(trmsg[sidBounce], trmsg[sidBounce2]), color, capgrpAmmostate);

               end;

            3: begin

               AddCaption(FormatA(trmsg[sidBounce], trmsg[sidBounce3]), color, capgrpAmmostate);

               end;

            4: begin

               AddCaption(FormatA(trmsg[sidBounce], trmsg[sidBounce4]), color, capgrpAmmostate);

               end;

            5: begin

               AddCaption(FormatA(trmsg[sidBounce], trmsg[sidBounce5]), color, capgrpAmmostate);

               end

            end;

        CurWeapon^.Bounciness:= bouncinessLevels[Gear^.MsgParam - 1];

        end

    else if (CurWeapon^.Propz and ammoprop_Timerable) <> 0 then

        begin

        CurWeapon^.Timer:= 1000 * Gear^.MsgParam;

        with CurrentTeam^ do

            ApplyAmmoChanges(Hedgehogs[CurrHedgehog]);

        end;

end;

// Return timer (in ticks) of hogs current ammo or MSGPARAM_INVALID

// if not timerable

function HHGetTimer(Gear: PGear): LongWord;

var CurWeapon: PAmmo;

begin

CurWeapon:= GetCurAmmoEntry(Gear^.Hedgehog^);

with Gear^.Hedgehog^ do

    if ((CurWeapon^.Propz and ammoprop_Timerable) <> 0) then

        HHGetTimer:= CurWeapon^.Timer

    else

        HHGetTimer:= MSGPARAM_INVALID;

end;

// Returns timer as a corresponding msgParam for /timer command

function HHGetTimerMsg(Gear: PGear): LongWord;

var timer: LongInt;

begin

timer:= HHGetTimer(Gear);

if timer > -1 then

    HHGetTimerMsg:= timer div 1000

else

    HHGetTimerMsg:= MSGPARAM_INVALID

end;

// Returns the selected bounciness value for the hog gear's current ammo

// or MSGPARAM_INVALID if current ammo has no settable bounciness

function HHGetBounciness(Gear: PGear): LongWord;

var CurWeapon: PAmmo;

begin

CurWeapon:= GetCurAmmoEntry(Gear^.Hedgehog^);

with Gear^.Hedgehog^ do

    if ((CurWeapon^.Propz and ammoprop_SetBounce) <> 0) then

        HHGetBounciness:= CurWeapon^.Bounciness

    else

        HHGetBounciness:= MSGPARAM_INVALID

end;

// Returns bounciness as a corresponding msgParam for /timer command

function HHGetBouncinessMsg(Gear: PGear): LongWord;

var bounciness, i: LongInt;

begin

    bounciness:= HHGetBounciness(Gear);

    if bounciness > -1 then

        for i:=0 to High(bouncinessLevels) do

            if bounciness = bouncinessLevels[i] then

                begin

                HHGetBouncinessMsg:= i+1;

                exit

                end;

    HHGetBouncinessMsg:= MSGPARAM_INVALID

end;

procedure Attack(Gear: PGear);

var xx, yy, newDx, newDy, lx, ly: hwFloat;

    speech: PVisualGear;

    newGear:  PGear;

    CurWeapon: PAmmo;

    usedAmmoType: TAmmoType;

    altUse: boolean;

    elastic: hwFloat;

begin

newGear:= nil;

bShowFinger:= false;

CurWeapon:= GetCurAmmoEntry(Gear^.Hedgehog^);

with Gear^,

    Gear^.Hedgehog^ do

        begin

        usedAmmoType:= CurAmmoType;

        if ((State and gstHHDriven) <> 0) and ((State and (gstAttacked or gstChooseTarget)) = 0) and (((State and gstMoving) = 0)

        or (Power > 0)

        or (CurAmmoType = amTeleport)

        or

        // Allow attacks while moving on ammo with AltAttack

        ((CurAmmoGear <> nil) and ((Ammoz[CurAmmoGear^.AmmoType].Ammo.Propz and ammoprop_AltAttack) <> 0))

        or ((Ammoz[CurAmmoType].Ammo.Propz and ammoprop_AttackInMove) <> 0))

        and ((TargetPoint.X <> NoPointX) or ((Ammoz[CurAmmoType].Ammo.Propz and ammoprop_NeedTarget) = 0)) then

            begin

            State:= State or gstAttacking;

            if (Power = cMaxPower) or ((Ammoz[CurAmmoType].Ammo.Propz and ammoprop_Power) = 0) then

                Message:= Message and (not gmAttack)

            else

                begin

                if Power = 0 then

                    begin

                    AttackBar:= CurrentTeam^.AttackBar;

                    PlaySound(sndThrowPowerUp)

                    end;

                inc(Power)

                end;

            if ((Message and gmAttack) <> 0) then

                exit;

            if (Ammoz[CurAmmoType].Ammo.Propz and ammoprop_Power) <> 0 then

                begin

                StopSound(sndThrowPowerUp);

                PlaySound(sndThrowRelease);

                end;

            xx:= SignAs(AngleSin(Angle), dX);

            yy:= -AngleCos(Angle);

            lx:= X + int2hwfloat(round(GetLaunchX(CurAmmoType, hwSign(dX), Angle)));

            ly:= Y + int2hwfloat(round(GetLaunchY(CurAmmoType, Angle)));

            if ((Gear^.State and gstHHHJump) <> 0) and (Effects[heArtillery] = 0) then

                xx:= - xx;

            if Ammoz[CurAmmoType].Ammo.AttackVoice <> sndNone then

                AddVoice(Ammoz[CurAmmoType].Ammo.AttackVoice, CurrentTeam^.voicepack);

// Initiating alt attack

            if  (CurAmmoGear <> nil)

            and ((Ammoz[CurAmmoGear^.AmmoType].Ammo.Propz and ammoprop_AltAttack) <> 0)

            and ((Gear^.Message and gmLJump) <> 0)

            and ((Ammoz[CurAmmoType].Ammo.Propz and ammoprop_AltUse) <> 0) then

                begin

                if (CurAmmoGear^.AmmoType = amJetpack) and (Gear^.Message and gmPrecise <> 0) then

                    begin

                    newDx:= xx*cMaxPower/cPowerDivisor;

                    newDy:= yy*cMaxPower/cPowerDivisor

                    end

                else

                    begin

                    newDx:= dX;

                    newDy:= dY

                    end;

                altUse:= true

                end

            else

                begin

                newDx:= xx*Power/cPowerDivisor;

                newDy:= yy*Power/cPowerDivisor;

                altUse:= false

                end;

            case CurAmmoType of

                      amGrenade: newGear:= AddGear(hwRound(lx), hwRound(ly), gtGrenade,         0, newDx, newDy, CurWeapon^.Timer);

                      amAirMine: newGear:= AddGear(hwRound(lx), hwRound(ly), gtAirMine,         0, newDx, newDy, 0);

                      amMolotov: newGear:= AddGear(hwRound(lx), hwRound(ly), gtMolotov,      0, newDx, newDy, 0);

                  amClusterBomb: newGear:= AddGear(hwRound(lx), hwRound(ly), gtClusterBomb,  0, newDx, newDy, CurWeapon^.Timer);

                      amGasBomb: newGear:= AddGear(hwRound(lx), hwRound(ly), gtGasBomb,      0, newDx, newDy, CurWeapon^.Timer);

                      amBazooka: newGear:= AddGear(hwRound(lx), hwRound(ly), gtShell,        0, newDx, newDy, 0);

                     amSnowball: newGear:= AddGear(hwRound(lx), hwRound(ly), gtSnowball,     0, newDx, newDy, 0);

                          amBee: newGear:= AddGear(hwRound(lx), hwRound(ly), gtBee,          0, newDx, newDy, 0);

                      amShotgun: begin

                                 PlaySound(sndShotgunReload);

                                 newGear:= AddGear(hwRound(lx), hwRound(ly), gtShotgunShot,  0, xx * _0_5, yy * _0_5, 0);

                                 end;

                   amPickHammer: newGear:= AddGear(hwRound(lx), hwRound(ly) + cHHRadius, gtPickHammer, 0, _0, _0, 0);

                         amSkip: ParseCommand('/skip', true);

                         amRope: newGear:= AddGear(hwRound(lx), hwRound(ly), gtRope, 0, xx, yy, 0);

                         amMine: newGear:= AddGear(hwRound(lx) + hwSign(dX) * 7, hwRound(ly), gtMine, gstWait, SignAs(_0_02, dX), _0, 0);

                        amSMine: newGear:= AddGear(hwRound(lx), hwRound(ly), gtSMine,    0, xx*Power/cPowerDivisor, yy*Power/cPowerDivisor, 0);

                        amKnife: begin

                                 newGear:= AddGear(hwRound(lx), hwRound(ly), gtKnife,    0, xx*Power/cPowerDivisor, yy*Power/cPowerDivisor, 0);

                                 newGear^.State:= newGear^.State or gstMoving;

                                 newGear^.Radius:= 4 // temporarily shrink so it doesn't instantly embed in the ground

                                 end;

                       amDEagle: newGear:= AddGear(hwRound(lx + xx * cHHRadius), hwRound(ly + yy * cHHRadius), gtDEagleShot, 0, xx * _0_5, yy * _0_5, 0);

                      amMinigun: begin

                                 PlaySound(sndMinigun);

                                 newGear:= AddGear(hwRound(lx + xx * cHHRadius), hwRound(ly + yy * cHHRadius), gtMinigun, 0, xx * _0_5, yy * _0_5, 0);

                                 end;

                      amSineGun: newGear:= AddGear(hwRound(lx + xx * cHHRadius), hwRound(ly + yy * cHHRadius), gtSineGunShot, 0, xx * _0_5, yy * _0_5, 0);

                    amPortalGun: begin

                                 newGear:= AddGear(hwRound(lx + xx * cHHRadius), hwRound(ly + yy * cHHRadius), gtPortal, 0, xx * _0_6, yy * _0_6,

                                 // set selected color

                                 CurWeapon^.Pos);

                                 end;

                  amSniperRifle: begin

                                 PlaySound(sndSniperReload);

                                 newGear:= AddGear(hwRound(lx + xx * cHHRadius), hwRound(ly + yy * cHHRadius), gtSniperRifleShot, 0, xx * _0_5, yy * _0_5, 0);

                                 end;

                     amDynamite: newGear:= AddGear(hwRound(lx) + hwSign(dX) * 7, hwRound(ly), gtDynamite, 0, SignAs(_0_03, dX), _0, 5000);

                      amCreeper: begin

                                 // TODO: Implement proper creeper spawning code. This is still the old rubber duck code.

                                 // Does it spawn inside water?

                                 if (LeftX > hwRound(Gear^.X) - Gear^.Karma) or (RightX < hwRound(Gear^.X) + Gear^.Karma) or (cWaterLine < hwRound(Gear^.Y) + Gear^.Karma) then

                                     PlaySound(sndDroplet2)

                                 else

                                     // spawned in air, normal drop sound

                                     PlaySound(sndCreeperDrop);

                                 newGear:= AddGear(hwRound(lx) + hwSign(dX) * 7, hwRound(ly), gtCreeper, 0, SignAs(_0_03, dX), _0, 0);

                                 if not ((not dX.isNegative) xor ((State and gstHHHJump) <> 0)) then

                                     newGear^.Tag:= -1

                                 else

                                     newGear^.Tag:= 1;

                                 end;

                    amFirePunch: newGear:= AddGear(hwRound(lx) + hwSign(dX) * 10, hwRound(ly), gtFirePunch, 0, xx, _0, 0);

                         amWhip: begin

                                 newGear:= AddGear(hwRound(lx) + hwSign(dX) * 10, hwRound(ly), gtWhip, 0, SignAs(_1, dX), - _0_8, 0);

                                 PlaySound(sndWhipCrack)

                                 end;

                       amHammer: begin

                                 newGear:= AddGear(hwRound(lx) + hwSign(dX) * 10, hwRound(ly), gtHammer, 0, SignAs(_1, dX), - _0_8, 0);

                                 PlaySound(sndWhack)

                                 end;

                  amBaseballBat: begin

                                 newGear:= AddGear(hwRound(lx) + hwSign(dX) * 10, hwRound(ly), gtShover, gsttmpFlag, xx * _0_5, yy * _0_5, 0);

                                 PlaySound(sndBaseballBat) // TODO: Only play if something is hit?

                                 end;

                    amParachute: begin

                                 newGear:= AddGear(hwRound(lx), hwRound(ly), gtParachute, 0, _0, _0, 0);

                                 PlaySound(sndParachute)

                                 end;

                    // we save CurWeapon^.Pos (in this case: cursor direction) by using it as (otherwise irrelevant) X value of the new gear.

                    amAirAttack: newGear:= AddGear(CurWeapon^.Pos, 0, gtAirAttack, 0, _0, _0, 0);

                   amMineStrike: newGear:= AddGear(CurWeapon^.Pos, 0, gtAirAttack, 1, _0, _0, 0);

                  amDrillStrike: newGear:= AddGear(CurWeapon^.Pos, 0, gtAirAttack, 3, _0, _0, CurWeapon^.Timer);

                       amNapalm: newGear:= AddGear(CurWeapon^.Pos, 0, gtAirAttack, 2, _0, _0, 0);

                    amBlowTorch: newGear:= AddGear(hwRound(lx), hwRound(ly), gtBlowTorch, 0, SignAs(_0_5, dX), _0, 0);

                       amGirder: newGear:= AddGear(0, 0, gtGirder, CurWeapon^.Pos, _0, _0, 0);

                       amRubber: begin

                                 newGear:= AddGear(0, 0, gtGirder, CurWeapon^.Pos, _0, _0, 0);

                                 newGear^.AmmoType:= amRubber

                                 end;

                     amTeleport: newGear:= AddGear(CurWeapon^.Pos, 0, gtTeleport, 0, _0, _0, 0);

                       amSwitch: newGear:= AddGear(hwRound(lx), hwRound(ly), gtSwitcher, 0, _0, _0, 0);

                       amMortar: begin

                                 playSound(sndMortar);

                                 newGear:= AddGear(hwRound(lx), hwRound(ly), gtMortar,  0, xx*cMaxPower/cPowerDivisor, yy*cMaxPower/cPowerDivisor, 0);

                                 end;

                      amRCPlane: begin

                                 newGear:= AddGear(hwRound(lx), hwRound(ly), gtRCPlane,  0, xx * cMaxPower / cPowerDivisor / 4, yy * cMaxPower / cPowerDivisor / 4, 0);

                                 newGear^.SoundChannel:= LoopSound(sndRCPlane)

                                 end;

                     amKamikaze: newGear:= AddGear(hwRound(lx), hwRound(ly), gtKamikaze, 0, xx * _0_5, yy * _0_5, 0);

                         amCake: newGear:= AddGear(hwRound(lx) + hwSign(dX) * 3, hwRound(ly), gtCake, 0, SignAs(cLittle, xx), _0, 0);

                    amSeduction: newGear:= AddGear(hwRound(lx), hwRound(ly), gtSeduction, 0, _0, _0, 0);

                   amWatermelon: newGear:= AddGear(hwRound(lx), hwRound(ly), gtWatermelon,  0, newDx, newDy, CurWeapon^.Timer);

                  amHellishBomb: newGear:= AddGear(hwRound(lx), hwRound(ly), gtHellishBomb,    0, newDx, newDy, 0);

                        amDrill: newGear:= AddGear(hwRound(lx), hwRound(ly), gtDrill, 0, newDx, newDy, 0);

                      amBallgun: newGear:= AddGear(hwRound(X), hwRound(Y), gtBallgun,  0, xx * _0_5, yy * _0_5, 0);

                      amJetpack: newGear:= AddGear(hwRound(lx), hwRound(ly), gtJetpack, 0, _0, _0, 0);

                        amBirdy: begin

                             PlaySound(sndWhistle);

                             newGear:= AddGear(hwRound(lx), hwRound(ly) - 32, gtBirdy, 0, _0, _0, 0);

                             end;

                   amLowGravity: begin

                                 PlaySound(sndLowGravity);

                                 cGravity:= cMaxWindSpeed;

                                 cGravityf:= 0.00025;

                                 cLowGravity := true

                                 end;

                  amExtraDamage: begin

                                 PlaySound(sndHellishImpact4);

                                 cDamageModifier:= _1_5

                                 end;

                 amInvulnerable: begin

                                 PlaySound(sndInvulnerable);

                                 Effects[heInvulnerable]:= 1

                                 end;

                    amExtraTime: begin

                                 PlaySound(sndExtraTime);

                                 if TurnTimeLeft <= (cMaxTurnTime - ExtraTime) then

                                     TurnTimeLeft:= TurnTimeLeft + ExtraTime

                                 else

                                     TurnTimeLeft:= cMaxTurnTime;

                                 end;

                   amLaserSight: begin

                                 PlaySound(sndLaserSight);

                                 cLaserSighting:= true

                                 end;

                     amVampiric: begin