(*

 * Hedgewars, a free turn based strategy game

 * Copyright (c) 2004-2014 Andrey Korotaev <unC0Rr@gmail.com>

 *

 * This program is free software; you can redistribute it and/or modify

 * it under the terms of the GNU General Public License as published by

 * the Free Software Foundation; version 2 of the License

 *

 * This program is distributed in the hope that it will be useful,

 * but WITHOUT ANY WARRANTY; without even the implied warranty of

 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

 * GNU General Public License for more details.

 *

 * You should have received a copy of the GNU General Public License

 * along with this program; if not, write to the Free Software

 * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA

 *)

{$INCLUDE "options.inc"}

unit uScript;

(*

 * This unit defines, implements and registers functions and

 * variables/constants bindings for usage in Lua scripts.

 *

 * Please keep http://code.google.com/p/hedgewars/wiki/LuaAPI up to date!

 *

 * Note: If you add a new function, make sure to test if _all_ parameters

 *       work as intended! (Especially conversions errors can sneak in

 *       unnoticed and render the parameter useless!)

 *)

interface

procedure ScriptPrintStack;

procedure ScriptClearStack;

procedure ScriptLoad(name : shortstring);

procedure ScriptOnPreviewInit;

procedure ScriptOnGameInit;

procedure ScriptOnScreenResize;

procedure ScriptSetInteger(name : shortstring; value : LongInt);

procedure ScriptSetString(name : shortstring; value : shortstring);

procedure ScriptCall(fname : shortstring);

function ScriptCall(fname : shortstring; par1: LongInt) : LongInt;

function ScriptCall(fname : shortstring; par1, par2: LongInt) : LongInt;

function ScriptCall(fname : shortstring; par1, par2, par3: LongInt) : LongInt;

function ScriptCall(fname : shortstring; par1, par2, par3, par4 : LongInt) : LongInt;

function ScriptExists(fname : shortstring) : boolean;

procedure LuaParseString(s: shortString);

//function ParseCommandOverride(key, value : shortstring) : shortstring;  This did not work out well

procedure initModule;

procedure freeModule;

implementation

{$IFDEF USE_LUA_SCRIPT}

uses LuaPas,

    uConsole,

    uConsts,

    uGears,

    uGearsList,

    uGearsUtils,

    uFloat,

    uWorld,

    uAmmos,

    uTeams,

    uSound,

    uChat,

    uStats,

    uStore,

    uRandom,

    uTypes,

    uVariables,

    uCommands,

    uUtils,

    uCaptions,

    uDebug,

    uCollisions,

    uRenderUtils,

    uTextures,

    uLandGraphics,

    SysUtils,

    uIO,

    uVisualGearsList,

    uGearsHandlersMess,

    uPhysFSLayer

{$IFNDEF PAS2C}

    , typinfo

{$ENDIF}

    ;

var luaState : Plua_State;

    ScriptAmmoLoadout : shortstring;

    ScriptAmmoProbability : shortstring;

    ScriptAmmoDelay : shortstring;

    ScriptAmmoReinforcement : shortstring;

    ScriptLoaded : boolean;

    mapDims : boolean;

procedure ScriptPrepareAmmoStore; forward;

procedure ScriptApplyAmmoStore; forward;

procedure ScriptSetAmmo(ammo : TAmmoType; count, probability, delay, reinforcement: Byte); forward;

procedure ScriptSetAmmoDelay(ammo : TAmmoType; delay: Byte); forward;

var LuaDebugInfo: lua_Debug;

procedure LuaParseString(s: shortString);

begin

    AddFileLog('[Lua] input string: ' + s);

    AddChatString(#3 + '[Lua] > ' + s);

    if luaL_dostring(luaState, Str2PChar(s)) <> 0 then

        begin

        AddFileLog('[Lua] input string parsing error!');

        AddChatString(#5 + '[Lua] Error while parsing!');

        end;

end;

function LuaUpdateDebugInfo(): Boolean;

begin

    FillChar(LuaDebugInfo, sizeof(LuaDebugInfo), 0);

    if lua_getstack(luaState, 1, @LuaDebugInfo) = 0 then

        exit(false); // stack not deep enough

    // get source name and line count

    lua_getinfo(luaState, PChar('Sl'), @LuaDebugInfo);

    exit(true);

end;

procedure LuaError(s: shortstring);

var src: shortstring;

const

    maxsrclen = 20;

begin

    if LuaUpdateDebugInfo() then

        begin

        src:= StrPas(LuaDebugInfo.source);

        s:= 'LUA ERROR [ ... '

            + copy(src, Length(src) - maxsrclen, maxsrclen - 3) + ':'

            + inttostr(LuaDebugInfo.currentLine) + ']: ' + s;

        end

    else

        s:= 'LUA ERROR: ' + s;

    WriteLnToConsole(s);

    AddChatString(#5 + s);

    if cTestLua then

        halt(HaltTestLuaError);

end;

procedure LuaCallError(error, call, paramsyntax: shortstring);

begin

    LuaError(call + ': ' + error);

    LuaError('-- SYNTAX: ' + call + ' ( ' + paramsyntax + ' )');

end;

procedure LuaParameterCountError(expected, call, paramsyntax: shortstring; wrongcount: LongInt); inline;

begin

    // TODO: i18n?

    LuaCallError('Wrong number of parameters! (is: ' + inttostr(wrongcount) + ', should be: '+ expected + ')', call, paramsyntax);

end;

// compare with allowed count

function CheckLuaParamCount(L : Plua_State; count: LongInt; call, paramsyntax: shortstring): boolean; inline;

var c: LongInt;

begin

    c:= lua_gettop(L);

    if c <> count then

        begin

        LuaParameterCountError('exactly ' + inttostr(count), call, paramsyntax, c);

        exit(false);

        end;

    CheckLuaParamCount:= true;

end;

// check if is either count1 or count2

function CheckAndFetchParamCount(L : Plua_State; count1, count2: LongInt; call, paramsyntax: shortstring; out actual: LongInt): boolean; inline;

begin

    actual:= lua_gettop(L);

    if (actual <> count1) and (actual <> count2) then

        begin

        LuaParameterCountError('either ' + inttostr(count1) + ' or ' + inttostr(count2), call, paramsyntax, actual);

        exit(false);

        end;

    CheckAndFetchParamCount:= true;

end;

// check if is same or higher as minCount

function CheckAndFetchLuaParamMinCount(L : Plua_State; minCount: LongInt; call, paramsyntax: shortstring; out actual: LongInt): boolean; inline;

begin

    actual:= lua_gettop(L);

    if (actual < minCount) then

        begin

        LuaParameterCountError(inttostr(minCount) + ' or more', call, paramsyntax, actual);

        exit(false);

        end;

    CheckAndFetchLuaParamMinCount:= true;

end;

function LuaToGearTypeOrd(L : Plua_State; i: LongInt; call, paramsyntax: shortstring): LongInt; inline;

begin

    if lua_isnoneornil(L, i) then i:= -1

    else i:= lua_tointeger(L, i);

    if (i < ord(Low(TGearType))) or (i > ord(High(TGearType))) then

        begin

        LuaCallError('Invalid gearType!', call, paramsyntax);

        LuaToGearTypeOrd:= -1;

        end

    else

        LuaToGearTypeOrd:= i;

end;

function LuaToVisualGearTypeOrd(L : Plua_State; i: LongInt; call, paramsyntax: shortstring): LongInt; inline;

begin

    if lua_isnoneornil(L, i) then i:= -1

    else i:= lua_tointeger(L, i);

    if (i < ord(Low(TVisualGearType))) or (i > ord(High(TVisualGearType))) then

        begin

        LuaCallError('Invalid visualGearType!', call, paramsyntax);

        LuaToVisualGearTypeOrd:= -1;

        end

    else

        LuaToVisualGearTypeOrd:= i;

end;

function LuaToAmmoTypeOrd(L : Plua_State; i: LongInt; call, paramsyntax: shortstring): LongInt; inline;

begin

    if lua_isnoneornil(L, i) then i:= -1

    else i:= lua_tointeger(L, i);

    if (i < ord(Low(TAmmoType))) or (i > ord(High(TAmmoType))) then

        begin

        LuaCallError('Invalid ammoType!', call, paramsyntax);

        LuaToAmmoTypeOrd:= -1;

        end

    else

        LuaToAmmoTypeOrd:= i;

end;

function LuaToStatInfoTypeOrd(L : Plua_State; i: LongInt; call, paramsyntax: shortstring): LongInt; inline;

begin

    if lua_isnoneornil(L, i) then i:= -1

    else i:= lua_tointeger(L, i);

    if (i < ord(Low(TStatInfoType))) or (i > ord(High(TStatInfoType))) then

        begin

        LuaCallError('Invalid statInfoType!', call, paramsyntax);

        LuaToStatInfoTypeOrd:= -1;

        end

    else

        LuaToStatInfoTypeOrd:= i;

end;

function LuaToSoundOrd(L : Plua_State; i: LongInt; call, paramsyntax: shortstring): LongInt; inline;

begin

    if lua_isnoneornil(L, i) then i:= -1

    else i:= lua_tointeger(L, i);

    if (i < ord(Low(TSound))) or (i > ord(High(TSound))) then

        begin

        LuaCallError('Invalid soundId!', call, paramsyntax);

        LuaToSoundOrd:= -1;

        end

    else

        LuaToSoundOrd:= i;

end;

function LuaToHogEffectOrd(L : Plua_State; i: LongInt; call, paramsyntax: shortstring): LongInt; inline;

begin

    if lua_isnoneornil(L, i) then i:= -1

    else i:= lua_tointeger(L, i);

    if (i < ord(Low(THogEffect))) or (i > ord(High(THogEffect))) then

        begin

        LuaCallError('Invalid gear type!', call, paramsyntax);

        LuaToHogEffectOrd:= -1;

        end

    else

        LuaToHogEffectOrd:= i;

end;

function LuaToCapGroupOrd(L : Plua_State; i: LongInt; call, paramsyntax: shortstring): LongInt; inline;

begin

    if lua_isnoneornil(L, i) then i:= -1

    else i:= lua_tointeger(L, i);

    if (i < ord(Low(TCapGroup))) or (i > ord(High(TCapGroup))) then

        begin

        LuaCallError('Invalid capgroup type!', call, paramsyntax);

        LuaToCapGroupOrd:= -1;

        end

    else

        LuaToCapGroupOrd:= i;

end;

function LuaToSpriteOrd(L : Plua_State; i: LongInt; call, paramsyntax: shortstring): LongInt; inline;

begin

    if lua_isnoneornil(L, i) then i:= -1

    else i:= lua_tointeger(L, i);

    if (i < ord(Low(TSprite))) or (i > ord(High(TSprite))) then

        begin

        LuaCallError('Invalid sprite id!', call, paramsyntax);

        LuaToSpriteOrd:= -1;

        end

    else

        LuaToSpriteOrd:= i;

end;

function LuaToMapGenOrd(L : Plua_State; i: LongInt; call, paramsyntax: shortstring): LongInt; inline;

begin

    if lua_isnoneornil(L, i) then i:= -1

    else i:= lua_tointeger(L, i);

    if (i < ord(Low(TMapGen))) or (i > ord(High(TMapGen))) then

        begin

        LuaCallError('Invalid mapgen id!', call, paramsyntax);

        LuaToMapGenOrd:= -1;

        end

    else

        LuaToMapGenOrd:= i;

end;

// wrapped calls //

// functions called from Lua:

// function(L : Plua_State) : LongInt; Cdecl;

// where L contains the state, returns the number of return values on the stack

// call CheckLuaParamCount or CheckAndFetchParamCount

// to validate/get the number of passed arguments (see their call definitions)

//

// use as return value the number of variables pushed back to the lua script

function lc_band(L: PLua_State): LongInt; Cdecl;

begin

    if CheckLuaParamCount(L, 2, 'band', 'value1, value2') then

        lua_pushinteger(L, lua_tointeger(L, 2) and lua_tointeger(L, 1))

    else

        lua_pushnil(L);

    lc_band := 1;

end;

function lc_bor(L: PLua_State): LongInt; Cdecl;

begin

    if CheckLuaParamCount(L, 2, 'bor', 'value1, value2') then

        lua_pushinteger(L, lua_tointeger(L, 2) or lua_tointeger(L, 1))

    else

        lua_pushnil(L);

    lc_bor := 1;

end;

function lc_bnot(L: PLua_State): LongInt; Cdecl;

begin

    if CheckLuaParamCount(L, 1, 'bnot', 'value') then

        lua_pushinteger(L, (not lua_tointeger(L, 1)))

    else

        lua_pushnil(L);

    lc_bnot := 1;

end;

function lc_div(L: PLua_State): LongInt; Cdecl;

begin

    if CheckLuaParamCount(L, 2, 'div', 'dividend, divisor') then

        lua_pushinteger(L, lua_tointeger(L, 1) div lua_tointeger(L, 2))

    else

        lua_pushnil(L);

    lc_div := 1;

end;

function lc_getinputmask(L : Plua_State) : LongInt; Cdecl;

begin

    if CheckLuaParamCount(L, 0, 'GetInputMask', '') then

        lua_pushinteger(L, InputMask);

    lc_getinputmask:= 1

end;

function lc_setinputmask(L : Plua_State) : LongInt; Cdecl;

begin

    if CheckLuaParamCount(L, 1, 'SetInputMask', 'mask') then

        InputMask:= lua_tointeger(L, 1);

    lc_setinputmask:= 0

end;

function lc_writelntoconsole(L : Plua_State) : LongInt; Cdecl;

begin

    if CheckLuaParamCount(L, 1, 'WriteLnToConsole', 'string') then

        WriteLnToConsole('Lua: ' + lua_tostring(L ,1));

    lc_writelntoconsole:= 0;

end;

function lc_parsecommand(L : Plua_State) : LongInt; Cdecl;

var t: PChar;

    i,c: LongWord;

    s: shortstring;

begin

    if CheckLuaParamCount(L, 1, 'ParseCommand', 'string') then

        begin

        t:= lua_tolstring(L, 1, Psize_t(@c));

        for i:= 1 to c do s[i]:= t[i-1];

        s[0]:= char(c);

        ParseCommand(s, true, true);

        end;

    lc_parsecommand:= 0;

end;

// sets weapon to the desired ammo type

function lc_setweapon(L : Plua_State) : LongInt; Cdecl;

var at: LongInt;

const

    call = 'SetWeapon';

    params = 'ammoType';

begin

    // no point to run this without any CurrentHedgehog

    if (CurrentHedgehog <> nil) and (CheckLuaParamCount(L, 1, call, params)) then

        begin

        at:= LuaToAmmoTypeOrd(L, 1, call, params);

        if at >= 0 then

            ParseCommand('setweap ' + char(at), true, true);

        end;

    lc_setweapon:= 0;

end;

// sets weapon to whatever weapons is next (wraps around, amSkip is skipped)

function lc_setnextweapon(L : Plua_State) : LongInt; Cdecl;

var at          : LongInt;

    nextAmmo    : TAmmo;

    s, a, cs, fa: LongInt;

const

    call = 'SetNextWeapon';

    params = '';

begin

    if (CurrentHedgehog <> nil) and (CheckLuaParamCount(L, 0, call, params)) then

        begin

        at:= -1;

        with CurrentHedgehog^ do

            begin

            cs:= 0; // current slot

            fa:= 0; // first ammo item to check

            // if something is selected, find it's successor

            if curAmmoType <> amNothing then

                begin

                // get current slot index

                cs:= Ammoz[CurAmmoType].Slot;

                // find current ammo index

                while (fa < cMaxSlotAmmoIndex)

                    and (Ammo^[cs, fa].AmmoType <> CurAmmoType) do

                        inc(fa);

                // increase once more because we won't successor

                inc(fa);

                end;

            // find first available ammo

            // revisit current slot too (current item might not be first)

            for s:= cs to cs + cMaxSlotIndex + 1 do

                begin

                for a:= fa to cMaxSlotAmmoIndex do

                    begin

                    // check if we went full circle

                    if (a = fa) and (s = cs + cMaxSlotIndex + 1)  then

                        exit(0);

                    // get ammo

                    nextAmmo:= Ammo^[s mod (cMaxSlotIndex + 1), a];

                    // only switch to ammos the hog actually has

                    if (nextAmmo.AmmoType <> amNothing)

                        and (nextAmmo.AmmoType <> amSkip) and (nextAmmo.Count > 0) then

                            begin

                            at:= ord(nextAmmo.AmmoType);

                            break;

                            end;

                    end;

                // stop slot loop if something was found

                if at >= 0 then

                    break;

                // check following slots starting with first item

                fa:= 0;

                end;

            end;

        if at >= 0 then

            ParseCommand('setweap ' + char(at), true, true);

        end;