Disable gfMoreWind for land objects on turn end only after a fixed-time delay
15s sounds much, but it's the average amount for gfMineStrike mines to settle
naturally. And it would be very confusing to see falling mines suddenly not
caring about gfMoreWind for no apparent reason.
Note this whole thing is a giant hack anyway, to prevent a turn being
blocked by infinitely bouncing mines.
The better solution would be to help gfMoreWind-affected land objects settle
naturally more reliably even under extreme wind.
But this commit is "good enough" for now.
If you don't like the delay, you can always tweak the constant.
' w32DownloadUnzip.vbs
' Download a zipfile and uncompress it with no external tools in Windows
'
' Copyright (c) 2012, Vittorio Giovara, <vittorio.giovara@gmail.com>
' Redistribution and use is allowed according to the terms of the BSD license.
'
' References
' http://superuser.com/questions/59465/is-it-possible-to-download-using-the-windows-command-line
' http://stackoverflow.com/questions/1021557/how-to-unzip-a-file-using-the-command-line
' http://stackoverflow.com/questions/424331/get-the-current-temporary-directory-path-in-vbscript
Set ArgObj = WScript.Arguments
If (Wscript.Arguments.Count = 1) Then
strFileURL = ArgObj(0)
strOutputPath = CreateObject("Scripting.FileSystemObject").GetAbsolutePathName(".")
Else
If (Wscript.Arguments.Count = 2) Then
strFileURL = ArgObj(0)
strOutputPath = ArgObj(1)
Else
WScript.Echo ("Usage: csript.exe w32DownloadUnzip.vbs url output")
WScript.Quit
End if
End if
' Temporary directory
strHDLocation = WScript.CreateObject("Scripting.FileSystemObject").GetSpecialFolder(2) + "\hwlibtemp.zip"
' Fetch the file
WScript.Echo ( "Trying to download from " & strFileURL)
Set objXMLHTTP = CreateObject("MSXML2.XMLHTTP")
objXMLHTTP.open "GET", strFileURL, false
objXMLHTTP.send()
If objXMLHTTP.Status = 200 Then
Set objADOStream = CreateObject("ADODB.Stream")
objADOStream.Open
objADOStream.Type = 1 'adTypeBinary
objADOStream.Write objXMLHTTP.ResponseBody
objADOStream.Position = 0 'Set the stream position to the start
Set objFSO = Createobject("Scripting.FileSystemObject")
If objFSO.Fileexists(strHDLocation) Then objFSO.DeleteFile strHDLocation
Set objFSO = Nothing
objADOStream.SaveToFile strHDLocation
objADOStream.Close
Set objADOStream = Nothing
Set objXMLHTTP = Nothing
Else
WScript.Echo ("Error downloading file (error code: " & objXMLHTTP.Status & ")")
Set objXMLHTTP = Nothing
WScript.Quit
End if
WScript.Echo ( "Extracting file to " & strOutputPath)
Set objShell = CreateObject( "Shell.Application" )
Set objSource = objShell.NameSpace(strHDLocation).Items()
Set objTarget = objShell.NameSpace(strOutputPath)
intOptions = 16 'no user prompt
objTarget.CopyHere objSource, intOptions
WScript.Echo ( "Success!" )
Set objShell = Nothing