(*

 * Hedgewars, a worms-like game

 * Copyright (c) 2004, 2005, 2006 Andrey Korotaev <unC0Rr@gmail.com>

 *

 * Distributed under the terms of the BSD-modified licence:

 *

 * Permission is hereby granted, free of charge, to any person obtaining a copy

 * of this software and associated documentation files (the "Software"), to deal

 * with the Software without restriction, including without limitation the

 * rights to use, copy, modify, merge, publish, distribute, sublicense, and/or

 * sell copies of the Software, and to permit persons to whom the Software is

 * furnished to do so, subject to the following conditions:

 *

 * 1. Redistributions of source code must retain the above copyright notice,

 *    this list of conditions and the following disclaimer.

 * 2. Redistributions in binary form must reproduce the above copyright notice,

 *    this list of conditions and the following disclaimer in the documentation

 *    and/or other materials provided with the distribution.

 * 3. The name of the author may not be used to endorse or promote products

 *    derived from this software without specific prior written permission.

 *

 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR IMPLIED

 * WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF

 * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO

 * EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,

 * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,

 * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;

 * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,

 * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR

 * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF

 * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

 *)

procedure doStepDrowningGear(Gear: PGear); forward;

function CheckGearDrowning(Gear: PGear): boolean;

begin

Result:= Gear.Y + Gear.Radius >= cWaterLine;

if Result then

   begin

   Gear.State:= gstDrowning;

   Gear.doStep:= doStepDrowningGear;

   PlaySound(sndSplash)

   end

end;

procedure CheckCollision(Gear: PGear);

begin

if TestCollisionXwithGear(Gear, hwSign(Gear.X)) or TestCollisionYwithGear(Gear, hwSign(Gear.Y))

   then Gear.State:= Gear.State or      gstCollision

   else Gear.State:= Gear.State and not gstCollision

end;

procedure CheckHHDamage(Gear: PGear);

begin

if Gear.dY > 0.40 then Gear.Damage:= Gear.Damage + 1 + round(70 * (abs(Gear.dY) - 0.40));

end;

////////////////////////////////////////////////////////////////////////////////

////////////////////////////////////////////////////////////////////////////////

procedure CalcRotationDirAngle(Gear: PGear);

var dAngle: Double;

begin

dAngle:= (abs(Gear.dX) + abs(Gear.dY))*0.1;

if Gear.dX >= 0 then Gear.DirAngle:= Gear.DirAngle + dAngle

                else Gear.DirAngle:= Gear.DirAngle - dAngle;

if Gear.DirAngle < 0 then Gear.DirAngle:= Gear.DirAngle + 16

else if Gear.DirAngle >= 16 then Gear.DirAngle:= Gear.DirAngle - 16

end;

////////////////////////////////////////////////////////////////////////////////

procedure doStepDrowningGear(Gear: PGear);

begin

AllInactive:= false;

Gear.Y:= Gear.Y + cDrownSpeed;

if round(Gear.Y) > Gear.Radius + cWaterLine + cVisibleWater then DeleteGear(Gear)

end;

////////////////////////////////////////////////////////////////////////////////

procedure doStepFallingGear(Gear: PGear);

var b: boolean;

begin

if TestCollisionYwithGear(Gear, hwSign(Gear.dY)) then

   begin

   Gear.dX:=   Gear.dX * Gear.Friction;

   Gear.dY:= - Gear.dY * Gear.Elasticity;

   b:= false

   end else b:= true;

if TestCollisionXwithGear(Gear, hwSign(Gear.dX)) then

   begin

   Gear.dX:= - Gear.dX * Gear.Elasticity;

//   Gear.dY:=   Gear.dY;

   b:= false

   end;

if b then

   begin

   Gear.dY:= Gear.dY + cGravity;

   Gear.State:= Gear.State and not gstCollision

   end else

   begin

   if sqr(Gear.dX) + sqr(Gear.dY) < 0.00001 then

      if (Gear.Timer = 0) then Gear.Active:= false

                          else begin

                          Gear.dX:= 0;

                          Gear.dY:= 0

                          end;

   Gear.State:= Gear.State or gstCollision

   end;

Gear.X:= Gear.X + Gear.dX;

Gear.Y:= Gear.Y + Gear.dY;

CheckGearDrowning(Gear);

if (sqr(Gear.dX) + sqr(Gear.dY) < 0.003) then Gear.State:= Gear.State and not gstMoving

                                         else Gear.State:= Gear.State or      gstMoving

end;

////////////////////////////////////////////////////////////////////////////////

procedure doStepCloud(Gear: PGear);

begin

Gear.X:= Gear.X + cWindSpeed * 200 + Gear.dX;

if Gear.Y > -160 then Gear.dY:= Gear.dY - 0.00002

                 else Gear.dY:= Gear.dY + 0.00002;

Gear.Y:= Gear.Y + Gear.dY;

if Gear.X < -cScreenWidth - 256 then Gear.X:= cScreenWidth + 2048 else

if Gear.X > cScreenWidth + 2048 then Gear.X:= -cScreenWidth - 256

end;

////////////////////////////////////////////////////////////////////////////////

procedure doStepBomb(Gear: PGear);

var i: integer;

begin

AllInactive:= false;

doStepFallingGear(Gear);

dec(Gear.Timer);

if Gear.Timer = 0 then

   begin

   case Gear.Kind of

        gtAmmo_Bomb: doMakeExplosion(round(Gear.X), round(Gear.Y), 50, EXPLAutoSound);

      gtClusterBomb: begin

                     doMakeExplosion(round(Gear.X), round(Gear.Y), 30, EXPLAutoSound);

                     for i:= 0 to 4 do

                         AddGear(round(Gear.X), round(Gear.Y), gtCluster, 0, (getrandom - 0.5)*0.2, (getrandom - 3) * 0.08);

                     end

        end;

   DeleteGear(Gear);

   exit

   end;

CalcRotationDirAngle(Gear);

if (Gear.State and (gstCollision or gstMoving)) = (gstCollision or gstMoving) then PlaySound(sndGrenadeImpact)

end;

procedure doStepCluster(Gear: PGear);

begin

AllInactive:= false;

doStepFallingGear(Gear);

if (Gear.State and gstCollision) <> 0 then

   begin

   doMakeExplosion(round(Gear.X), round(Gear.Y), 20, EXPLAutoSound);

   DeleteGear(Gear);

   exit

   end;

if (GameTicks and $1F) = 0 then

   AddGear(round(Gear.X), round(Gear.Y), gtSmokeTrace, 0)

end;

////////////////////////////////////////////////////////////////////////////////

procedure doStepGrenade(Gear: PGear);

begin

AllInactive:= false;

Gear.dX:= Gear.dX + cWindSpeed;

doStepFallingGear(Gear);

if (Gear.State and gstCollision) <> 0 then

   begin

   doMakeExplosion(round(Gear.X), round(Gear.Y), 50, EXPLAutoSound);

   DeleteGear(Gear);

   exit

   end;

if (GameTicks and $3F) = 0 then

   AddGear(round(Gear.X), round(Gear.Y), gtSmokeTrace, 0)

end;

////////////////////////////////////////////////////////////////////////////////

procedure doStepHealthTagWork(Gear: PGear);

begin

AllInactive:= false;

dec(Gear.Timer);

Gear.Y:= Gear.Y - 0.07;

if Gear.Timer = 0 then

   begin

   PHedgehog(Gear.Hedgehog).Gear.Active:= true;

   DeleteGear(Gear)

   end

end;

procedure doStepHealthTag(Gear: PGear);

var s: shortstring;

begin

AllInactive:= false;

str(Gear.State, s);

Gear.Surf:= RenderString(s, PHedgehog(Gear.Hedgehog).Team.Color, fnt16);

Gear.doStep:= doStepHealthTagWork

end;

////////////////////////////////////////////////////////////////////////////////

procedure doStepGrave(Gear: PGear);

begin

AllInactive:= false;

if Gear.dY < 0 then

   if TestCollisionY(Gear, -1) then Gear.dY:= 0;

if Gear.dY >=0 then

   if TestCollisionY(Gear, 1) then

      begin

      Gear.dY:= - Gear.dY * Gear.Elasticity;

      if Gear.dY > - 0.001 then

         begin

         Gear.Active:= false;

         exit

         end else if Gear.dY < - 0.03 then PlaySound(sndGraveImpact)

      end;

Gear.Y:= Gear.Y + Gear.dY;

CheckGearDrowning(Gear);

Gear.dY:= Gear.dY + cGravity

end;

////////////////////////////////////////////////////////////////////////////////

procedure doStepUFOWork(Gear: PGear);

var t: Double;

begin

AllInactive:= false;

t:= sqrt(sqr(Gear.dX) + sqr(Gear.dY));

Gear.dX:= Gear.Elasticity * (Gear.dX + 0.000004 * (TargetPoint.X - trunc(Gear.X)));

Gear.dY:= Gear.Elasticity * (Gear.dY + 0.000004 * (TargetPoint.Y - trunc(Gear.Y)));

t:= t / (sqrt(sqr(Gear.dX) + sqr(Gear.dY)));

Gear.dX:= Gear.dX * t;

Gear.dY:= Gear.dY * t;

Gear.X:= Gear.X + Gear.dX;

Gear.Y:= Gear.Y + Gear.dY;

CheckCollision(Gear);

dec(Gear.Timer);

if ((Gear.State and gstCollision) <> 0) or (Gear.Timer = 0) then

   begin

   doMakeExplosion(round(Gear.X), round(Gear.Y), 50, EXPLAutoSound);

   DeleteGear(Gear);

   end;

end;

procedure doStepUFO(Gear: PGear);

begin

AllInactive:= false;

Gear.X:= Gear.X + Gear.dX;

Gear.Y:= Gear.Y + Gear.dY;

Gear.dY:= Gear.dY + cGravity;

CheckCollision(Gear);

if (Gear.State and gstCollision) <> 0 then

   begin

   doMakeExplosion(round(Gear.X), round(Gear.Y), 50, EXPLAutoSound);

   DeleteGear(Gear);

   exit

   end;

dec(Gear.Timer);

if Gear.Timer = 0 then

   begin

   Gear.Timer:= 5000;

   Gear.doStep:= doStepUFOWork

   end;

end;

////////////////////////////////////////////////////////////////////////////////

procedure doStepShotgunShot(Gear: PGear);

var i: LongWord;

begin

AllInactive:= false;

if Gear.Timer > 0 then

   begin

   dec(Gear.Timer);

   if Gear.Timer = 0 then PlaySound(sndShotgunFire);

   exit

   end;

i:= 200;

repeat

Gear.X:= Gear.X + Gear.dX;

Gear.Y:= Gear.Y + Gear.dY;

CheckCollision(Gear);

if (Gear.State and gstCollision) <> 0 then

   begin

   AmmoShove(Gear, 25, 25);

   doMakeExplosion(round(Gear.X), round(Gear.Y), 25, EXPLNoDamage or EXPLDoNotTouchHH);

   DeleteGear(Gear);

   AfterAttack;

   exit

   end;

dec(i)

until i = 0;

if (Gear.X < 0) or (Gear.Y < 0) or (Gear.X > 2048) or (Gear.Y > 1024) then

   begin

   DeleteGear(Gear);

   AfterAttack

   end

end;

////////////////////////////////////////////////////////////////////////////////

procedure doStepDEagleShot(Gear: PGear);

var i, x, y: LongWord;

    oX, oY: Double;

begin

AllInactive:= false;

i:= 80;

oX:= Gear.X;

oY:= Gear.Y;

repeat

  Gear.X:= Gear.X + Gear.dX;

  Gear.Y:= Gear.Y + Gear.dY;

  x:= round(Gear.X);

  y:= round(Gear.Y);

  if ((y and $FFFFFC00) = 0) and ((x and $FFFFF800) = 0)

     and (Land[y, x] <> 0) then inc(Gear.Damage);

  AmmoShove(Gear, 7, 20);

  dec(i)

until (i = 0) or (Gear.Damage > Gear.Health);

if Gear.Damage > 0 then

   begin

   DrawTunnel(oX, oY, Gear.dX, Gear.dY, 82 - i, 1);

   dec(Gear.Health, Gear.Damage);

   Gear.Damage:= 0

   end;

if (Gear.Health <= 0) or (Gear.X < 0) or (Gear.Y < 0) or (Gear.X > 2048) or (Gear.Y > 1024) then

   DeleteGear(Gear)

end;

////////////////////////////////////////////////////////////////////////////////

procedure doStepActionTimer(Gear: PGear);

begin

dec(Gear.Timer);

case Gear.Kind of

    gtATStartGame: begin

                   AllInactive:= false;

                   if Gear.Timer = 0 then

                      AddCaption(trmsg[sidStartFight], $FFFFFF, capgrpGameState);

                   end;

 gtATSmoothWindCh: begin

                   if Gear.Timer = 0 then

                      begin

                      if WindBarWidth < Gear.Tag then inc(WindBarWidth)

                         else if WindBarWidth > Gear.Tag then dec(WindBarWidth);

                      if WindBarWidth <> Gear.Tag then Gear.Timer:= 10;

                      end

                   end;

   gtATFinishGame: begin

                   AllInactive:= false;

                   if Gear.Timer = 0 then

                      GameState:= gsExit

                   end;

     end;

if Gear.Timer = 0 then DeleteGear(Gear)

end;

////////////////////////////////////////////////////////////////////////////////

procedure doStepPickHammerWork(Gear: PGear);

var i, ei: integer;

    HHGear: PGear;

begin

AllInactive:= false;

dec(Gear.Timer);

if (Gear.Timer = 0)or((Gear.Message and gm_Destroy) <> 0) then

   begin

   DeleteGear(Gear);

   AfterAttack;

   exit

   end;

HHGear:= PHedgehog(Gear.Hedgehog).Gear;

if (Gear.Timer and $3F) = 0 then

   begin

   i:= round(Gear.X) - Gear.Radius  - GetRandom(2);

   ei:= round(Gear.X) + Gear.Radius + GetRandom(2);

   while i <= ei do

         begin

         doMakeExplosion(i, round(Gear.Y) + 3, 3, 0);

         inc(i, 1)

         end;

   Gear.X:= Gear.X + Gear.dX;

   Gear.Y:= Gear.Y + 1.9;

   SetAllHHToActive;

   end;

if TestCollisionYwithGear(Gear, 1) then

   begin

   Gear.dY:= 0;

   HHGear.dX:= 0.0000001 * hwSign(PGear(Gear.Hedgehog).dX);

   HHGear.dY:= 0;

   end else

   begin

   Gear.dY:= Gear.dY + cGravity;

   Gear.Y:= Gear.Y + Gear.dY;

   if Gear.Y > 1024 then Gear.Timer:= 1

   end;

Gear.X:= Gear.X + HHGear.dX;

HHGear.X:= Gear.X;

HHGear.Y:= Gear.Y - cHHRadius;

if (Gear.Message and gm_Attack) <> 0 then

   if (Gear.State and gsttmpFlag) <> 0 then Gear.Timer:= 1 else else

   if (Gear.State and gsttmpFlag) = 0 then Gear.State:= Gear.State or gsttmpFlag;

if ((Gear.Message and gm_Left) <> 0) then Gear.dX:= -0.3 else

   if ((Gear.Message and gm_Right) <> 0) then Gear.dX:= 0.3

                                         else Gear.dX:= 0;

end;

procedure doStepPickHammer(Gear: PGear);

var i, y: integer;

    ar: TRangeArray;

begin

i:= 0;

y:= round(Gear.Y) - cHHRadius*2;

while y < round(Gear.Y) do

   begin

   ar[i].Left := round(Gear.X) - Gear.Radius - GetRandom(2);

   ar[i].Right:= round(Gear.X) + Gear.Radius + GetRandom(2);

   inc(y, 2);

   inc(i)

   end;

DrawHLinesExplosions(@ar, 3, round(Gear.Y) - cHHRadius*2, 2, Pred(i));

Gear.dY:= PHedgehog(Gear.Hedgehog).Gear.dY;

doStepPickHammerWork(Gear);

Gear.doStep:= doStepPickHammerWork

end;

////////////////////////////////////////////////////////////////////////////////

procedure doStepRopeWork(Gear: PGear);

const flCheck: boolean = false;

var HHGear: PGear;

    len, cs, cc, tx, ty: Double;

    lx, ly: LongInt;

    procedure DeleteMe;

    begin

      with HHGear^ do

           begin

           Message:= Message and not gm_Attack;

           State:= State or gstFalling;

           end;

      DeleteGear(Gear);

    end;

begin

HHGear:= PHedgehog(Gear.Hedgehog).Gear;

if ((HHGear.State and gstHHDriven) = 0)

   or (CheckGearDrowning(HHGear)) then

   begin

   DeleteMe;

   exit

   end;

Gear.dX:= HHGear.X - Gear.X;

Gear.dY:= HHGear.Y - Gear.Y;

if (Gear.Message and gm_Left  <> 0) then HHGear.dX:= HHGear.dX - 0.0002 else

if (Gear.Message and gm_Right <> 0) then HHGear.dX:= HHGear.dX + 0.0002;

if not TestCollisionYwithGear(HHGear, 1) then HHGear.dY:= HHGear.dY + cGravity;

cs:= Gear.dY + HHGear.dY;

cc:= Gear.dX + HHGear.dX;

len:= 1 / sqrt(sqr(cc)+sqr(cs));

cc:= cc * len;

cs:= cs * len;

flCheck:= not flCheck;

if flCheck then  // check whether rope needs dividing

   begin

   len:= Gear.Elasticity - 20;

   while len > 5 do

         begin

         tx:= cc*len;

         ty:= cs*len;

         lx:= round(Gear.X + tx) + hwSign(HHGear.dX);

         ly:= round(Gear.Y + ty) + hwSign(HHGear.dY);

         if ((ly and $FFFFFC00) = 0) and ((lx and $FFFFF800) = 0)and (Land[ly, lx] <> 0) then

           begin

           with RopePoints.ar[RopePoints.Count] do

                begin

                X:= Gear.X;

                Y:= Gear.Y;

                if RopePoints.Count = 0 then RopePoints.HookAngle:= DxDy2Angle32(Gear.dY, Gear.dX);

                b:= (cc * HHGear.dY) > (cs * HHGear.dX);