(*

 * Hedgewars, a free turn based strategy game

 * Copyright (c) 2004-2015 Andrey Korotaev <unC0Rr@gmail.com>

 *

 * This program is free software; you can redistribute it and/or modify

 * it under the terms of the GNU General Public License as published by

 * the Free Software Foundation; version 2 of the License

 *

 * This program is distributed in the hope that it will be useful,

 * but WITHOUT ANY WARRANTY; without even the implied warranty of

 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

 * GNU General Public License for more details.

 *

 * You should have received a copy of the GNU General Public License

 * along with this program; if not, write to the Free Software

 * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA

 *)

{$INCLUDE "options.inc"}

unit uTeams;

interface

uses uConsts, uInputHandler, uRandom, uFloat, uStats,

     uCollisions, uSound, uStore, uTypes, uScript

     {$IFDEF USE_TOUCH_INTERFACE}, uWorld{$ENDIF};

procedure initModule;

procedure freeModule;

function  AddTeam(TeamColor: Longword): PTeam;

function  SetMissionTeam(): PTeam;

procedure SwitchHedgehog;

procedure AfterSwitchHedgehog;

procedure InitTeams;

function  TeamSize(p: PTeam): Longword;

procedure RecountTeamHealth(team: PTeam);

procedure RecountAllTeamsHealth();

procedure RestoreHog(HH: PHedgehog);

procedure RestoreTeamsFromSave;

function  CheckForWin: boolean;

procedure TeamGoneEffect(var Team: TTeam);

procedure SwitchCurrentHedgehog(newHog: PHedgehog);

var MaxTeamHealth: LongInt;

implementation

uses uLocale, uAmmos, uChat, uVariables, uUtils, uIO, uCaptions, uCommands, uDebug,

    uGearsUtils, uGearsList, uVisualGearsList, uTextures

    {$IFDEF USE_TOUCH_INTERFACE}, uTouch{$ENDIF};

var TeamsGameOver: boolean;

    NextClan: boolean;

    SwapClanPre, SwapClanReal: LongInt;

function CheckForWin: boolean;

var AliveClan: PClan;

    s, cap: ansistring;

    ts: array[0..(cMaxTeams - 1)] of ansistring;

    t, ActiveAliveCount, i, j: LongInt;

    allWin, winCamera: boolean;

begin

CheckForWin:= false;

ActiveAliveCount:= 0;

// Victory if there is 1 living and non-passive clan left

for t:= 0 to Pred(ClansCount) do

    if (ClansArray[t]^.ClanHealth > 0) and (not ClansArray[t]^.Passive) then

        begin

        inc(ActiveAliveCount);

        AliveClan:= ClansArray[t]

        end;

// Exception: gfOneClanMode, then there is no winner

if (ActiveAliveCount > 1) or ((ActiveAliveCount = 1) and ((GameFlags and gfOneClanMode) <> 0)) then

    exit;

CheckForWin:= true;

TurnTimeLeft:= 0;

ReadyTimeLeft:= 0;

// If the game ends during a multishot, or after the Sudden Death

// water has risen, do last turn stats / reaction.

if ((not bBetweenTurns) and isInMultiShoot) or (bDuringWaterRise) then

    begin

    TurnStats();

    if (not bDuringWaterRise) then

        TurnReaction();

    TurnStatsReset();

    end;

if not TeamsGameOver then

    begin

    if ActiveAliveCount = 0 then

        begin // draw

        AddCaption(GetEventString(eidRoundDraw), capcolDefault, capgrpGameState);

        if SendGameResultOn then

            SendStat(siGameResult, shortstring(trmsg[sidDraw]));

        if PreviousTeam <> nil then

            AddVoice(sndStupid, PreviousTeam^.voicepack)

        else

            AddVoice(sndStupid, TeamsArray[0]^.voicepack);

        AddGear(0, 0, gtATFinishGame, 0, _0, _0, 3000);

        end

    else // win

        begin

        allWin:= false;

        with AliveClan^ do

            begin

            if TeamsNumber = 1 then // single team wins

                begin

                s:= ansistring(Teams[0]^.TeamName);

                // Victory caption is randomly selected

                cap:= FormatA(GetEventString(eidRoundWin), s);

                AddCaption(cap, capcolDefault, capgrpGameState);

                s:= FormatA(trmsg[sidWinner], s);

                end

            else // clan with at least 2 teams wins

                begin

                s:= '';

                for j:= 0 to Pred(TeamsNumber) do

                    begin

                    ts[j] := Teams[j]^.TeamName;

                    end;

                // Write victory message for caption and stats page

                if (TeamsNumber = cMaxTeams) or (TeamsCount = TeamsNumber) then

                    begin

                    // No enemies for some reason ... Everyone wins!!1!

                    s:= trmsg[sidWinnerAll];

                    allWin:= true;

                    end

                else if (TeamsNumber >= 2) and (TeamsNumber < cMaxTeams) then

                    // List all winning teams in a list

                    if (TeamsNumber = 2) then

                        s:= FormatA(trmsg[TMsgStrId(sidWinner2)], ts[0], ts[1])

                    else if (TeamsNumber = 3) then

                        s:= FormatA(trmsg[TMsgStrId(sidWinner3)], ts[0], ts[1], ts[2])

                    else if (TeamsNumber = 4) then

                        s:= FormatA(trmsg[TMsgStrId(sidWinner4)], ts[0], ts[1], ts[2], ts[3])

                    else if (TeamsNumber = 5) then

                        s:= FormatA(trmsg[TMsgStrId(sidWinner5)], ts[0], ts[1], ts[2], ts[3], ts[4])

                    else if (TeamsNumber = 6) then

                        s:= FormatA(trmsg[TMsgStrId(sidWinner6)], ts[0], ts[1], ts[2], ts[3], ts[4], ts[5])

                    else if (TeamsNumber = 7) then

                        s:= FormatA(trmsg[TMsgStrId(sidWinner7)], ts[0], ts[1], ts[2], ts[3], ts[4], ts[5], ts[6]);

                // The winner caption is the same as the stats message and not randomized

                cap:= s;

                AddCaption(cap, capcolDefault, capgrpGameState);

                // TODO (maybe): Show victory animation/captions per-team instead of all winners at once?

                end;

            // Enable winner state for winning hogs and move camera to a winning hedgehog

            winCamera:= false;

            for j:= 0 to Pred(TeamsNumber) do

                with Teams[j]^ do

                    for i:= 0 to cMaxHHIndex do

                        with Hedgehogs[i] do

                            if (Gear <> nil) then

                                begin

                                if (not winCamera) then

                                    begin

                                    FollowGear:= Gear;

                                    winCamera:= true;

                                    end;

                                Gear^.State:= gstWinner;

                                end;

            if Flawless then

                AddVoice(sndFlawless, Teams[0]^.voicepack)

            else

                AddVoice(sndVictory, Teams[0]^.voicepack);

            end;

        if SendGameResultOn then

            SendStat(siGameResult, shortstring(s));

        if allWin and SendAchievementsStatsOn then

            SendStat(siEverAfter, '');

        AddGear(0, 0, gtATFinishGame, 0, _0, _0, 3000)

        end;

    SendStats;

    end;

TeamsGameOver:= true;

GameOver:= true

end;

procedure SwitchHedgehog;

var c, i, t: LongWord;

    PrevHH, PrevTeam : LongWord;

begin

TargetPoint.X:= NoPointX;

if checkFails(CurrentTeam <> nil, 'Team is nil!', true) then exit;

with CurrentHedgehog^ do

    if (PreviousTeam <> nil) and PlacingHogs and Unplaced then

        begin

        Unplaced:= false;

        if Gear <> nil then

           begin

           DeleteCI(Gear);

           FindPlace(Gear, false, 0, LAND_WIDTH, true);

           if Gear <> nil then

               AddCI(Gear)

           end

        end

    else if (PreviousTeam <> nil) and PlacingKings and UnplacedKing then

        UnplacedKing:= false;

PreviousTeam:= CurrentTeam;

with CurrentHedgehog^ do

    begin

    if Gear <> nil then

        begin

        MultiShootAttacks:= 0;

        Gear^.Message:= 0;

        Gear^.Z:= cHHZ;

        RemoveGearFromList(Gear);

        InsertGearToList(Gear)

        end

    end;

// Try to make the ammo menu viewed when not your turn be a bit more useful for per-hog-ammo mode

with CurrentTeam^ do

    if ((GameFlags and gfPerHogAmmo) <> 0) and (not ExtDriven) and (CurrentHedgehog^.BotLevel = 0) then

        begin

        c:= CurrHedgehog;

        repeat

            begin

            inc(c);

            if c > cMaxHHIndex then

                c:= 0

            end

        until (c = CurrHedgehog) or (Hedgehogs[c].Gear <> nil) and (Hedgehogs[c].Effects[heFrozen] < 50255);

        LocalAmmo:= Hedgehogs[c].AmmoStore

        end;

c:= CurrentTeam^.Clan^.ClanIndex;

repeat

    if (GameFlags and gfTagTeam) <> 0 then

        begin

        with ClansArray[c]^ do

            begin

            if (CurrTeam = TagTeamIndex) then

                begin

                TagTeamIndex:= Pred(TagTeamIndex) mod TeamsNumber;

                CurrTeam:= Pred(CurrTeam) mod TeamsNumber;

                inc(c);

                if c = ClansCount then

                    c:= 0;

                if c = SwapClanReal then

                    inc(TotalRoundsReal);

                NextClan:= true;

                end;

            end;

        with ClansArray[c]^ do

            begin

            if (not PlacingHogs) and (not PlacingKings) and ((Succ(CurrTeam) mod TeamsNumber) = TagTeamIndex) then

                begin

                if c = SwapClanPre then

                    inc(TotalRoundsPre);

                end;

            end;

        end

    else

        begin

        inc(c);

        if c = ClansCount then

            c:= 0;

        if (not PlacingHogs) and (not PlacingKings) then

            begin

            if c = SwapClanPre then

                inc(TotalRoundsPre);

            if c = SwapClanReal then

                inc(TotalRoundsReal);

            end;

        end;

    with ClansArray[c]^ do

        begin

        PrevTeam:= CurrTeam;

        repeat

            CurrTeam:= Succ(CurrTeam) mod TeamsNumber;

            CurrentTeam:= Teams[CurrTeam];

            with CurrentTeam^ do

                if (not Passive) then

                    begin

                    PrevHH:= CurrHedgehog mod HedgehogsNumber; // prevent infinite loop when CurrHedgehog = 7, but HedgehogsNumber < 8 (team is destroyed before its first turn)

                    repeat

                        CurrHedgehog:= Succ(CurrHedgehog) mod HedgehogsNumber;

                    until ((Hedgehogs[CurrHedgehog].Gear <> nil) and (Hedgehogs[CurrHedgehog].Effects[heFrozen] < 256)) or (CurrHedgehog = PrevHH)

                    end

        until ((not CurrentTeam^.Passive) and (CurrentTeam^.Hedgehogs[CurrentTeam^.CurrHedgehog].Gear <> nil) and (CurrentTeam^.Hedgehogs[CurrentTeam^.CurrHedgehog].Effects[heFrozen] < 256)) or (PrevTeam = CurrTeam) or ((CurrTeam = TagTeamIndex) and ((GameFlags and gfTagTeam) <> 0))

        end;

        if (CurrentTeam^.Passive) or (CurrentTeam^.Hedgehogs[CurrentTeam^.CurrHedgehog].Gear = nil) or (CurrentTeam^.Hedgehogs[CurrentTeam^.CurrHedgehog].Effects[heFrozen] > 255) then

            begin

            with CurrentTeam^.Clan^ do

                for t:= 0 to Pred(TeamsNumber) do

                    with Teams[t]^ do

                        for i:= 0 to Pred(HedgehogsNumber) do

                            with Hedgehogs[i] do

                                begin

                                if Effects[heFrozen] > 255 then Effects[heFrozen]:= max(255,Effects[heFrozen]-50000);

                                if (Gear <> nil) and (Effects[heFrozen] < 256) and (CurrentTeam^.Hedgehogs[CurrentTeam^.CurrHedgehog].Effects[heFrozen] > 255) then

                                    CurrHedgehog:= i

                                end;

            if (not CurrentTeam^.Passive) and ((CurrentTeam^.Hedgehogs[CurrentTeam^.CurrHedgehog].Gear = nil) or (CurrentTeam^.Hedgehogs[CurrentTeam^.CurrHedgehog].Effects[heFrozen] > 255)) then

                inc(CurrentTeam^.Clan^.TurnNumber);

            end;

until (not CurrentTeam^.Passive) and (CurrentTeam^.Hedgehogs[CurrentTeam^.CurrHedgehog].Gear <> nil) and (CurrentTeam^.Hedgehogs[CurrentTeam^.CurrHedgehog].Effects[heFrozen] < 256);

SwitchCurrentHedgehog(@(CurrentTeam^.Hedgehogs[CurrentTeam^.CurrHedgehog]));

{$IFDEF USE_TOUCH_INTERFACE}

if (Ammoz[CurrentHedgehog^.CurAmmoType].Ammo.Propz and ammoprop_NoCrosshair) = 0 then

    begin

    if not(arrowUp.show) then

        begin

        animateWidget(@arrowUp, true, true);

        animateWidget(@arrowDown, true, true);

        end;

    end

else

    if arrowUp.show then

        begin

        animateWidget(@arrowUp, true, false);

        animateWidget(@arrowDown, true, false);

        end;

{$ENDIF}

AmmoMenuInvalidated:= true;

end;

procedure AfterSwitchHedgehog;

var i, t: LongInt;

    CurWeapon: PAmmo;

    w: real;

    vg: PVisualGear;

    g: PGear;

    s: ansistring;

begin

if PlacingHogs or PlacingKings then

    begin

    PlacingHogs:= false;

    PlacingKings:= false;

    for t:= 0 to Pred(TeamsCount) do

        for i:= 0 to cMaxHHIndex do

            if ((GameFlags and gfPlaceHog) <> 0) and (TeamsArray[t]^.Hedgehogs[i].Gear <> nil) and (TeamsArray[t]^.Hedgehogs[i].Unplaced) then

                PlacingHogs:= true

            else if ((GameFlags and gfPlaceHog) = 0) and ((GameFlags and gfKing) <> 0) and (TeamsArray[t]^.Hedgehogs[i].Gear <> nil) and (TeamsArray[t]^.Hedgehogs[i].UnplacedKing) then

                PlacingKings:= true;

    if (not PlacingHogs) and (not PlacingKings) then // Reset various things I mucked with

        begin

        for i:= 0 to ClansCount do

            if ClansArray[i] <> nil then

                begin

                ClansArray[i]^.TurnNumber:= 0;

                end;

        ResetWeapons

        end;

    end;

if (not PlacingHogs) and (not PlacingKings) then

    begin

    if (TotalRoundsReal = -1) then

        TotalRoundsReal:= 0;

    if (TotalRoundsPre = -1) and (ClansCount = 1) then

        TotalRoundsPre:= 0;

    end;

// Determine clan ID to check to determine whether to increase TotalRoundsPre/TotalRoundsReal

if (not PlacingHogs) and (not PlacingKings) then

    begin

    if SwapClanPre = -1 then

        begin

        if (GameFlags and gfRandomOrder) <> 0 then

            SwapClanPre:= 0

        else

            SwapClanPre:= ClansCount - 1;

        end;

    if SwapClanReal = -1 then

        SwapClanReal:= CurrentTeam^.Clan^.ClanIndex;

    end;

inc(CurrentTeam^.Clan^.TurnNumber);

with CurrentTeam^.Clan^ do

    for t:= 0 to Pred(TeamsNumber) do

        with Teams[t]^ do

            for i:= 0 to Pred(HedgehogsNumber) do

                with Hedgehogs[i] do

                    if Effects[heFrozen] > 255 then

                        Effects[heFrozen]:= max(255,Effects[heFrozen]-50000);

CurWeapon:= GetCurAmmoEntry(CurrentHedgehog^);

if CurWeapon^.Count = 0 then

    CurrentHedgehog^.CurAmmoType:= amNothing;

with CurrentHedgehog^ do

    begin

    with Gear^ do

        begin

        Z:= cCurrHHZ;

        State:= gstHHDriven;

        Active:= true;

        Power:= 0;

        LastDamage:= nil

        end;

    RemoveGearFromList(Gear);

    InsertGearToList(Gear);

    FollowGear:= Gear

    end;

if (GameFlags and gfDisableWind) = 0 then

    begin

    cWindSpeed:= rndSign(GetRandomf * 2 * cMaxWindSpeed);

    w:= hwFloat2Float(cWindSpeed);

    vg:= AddVisualGear(0, 0, vgtSmoothWindBar);

    if vg <> nil then vg^.dAngle:= w;

    AddFileLog('Wind = '+FloatToStr(cWindSpeed));

    end;

ApplyAmmoChanges(CurrentHedgehog^);

if (not CurrentTeam^.ExtDriven) and (CurrentHedgehog^.BotLevel = 0) then

    SetBinds(CurrentTeam^.Binds);

if PlacingHogs then

    begin

    if CurrentHedgehog^.Unplaced then

        TurnTimeLeft:= 15000

    else TurnTimeLeft:= 0

    end

else if PlacingKings then

    if CurrentHedgehog^.King and CurrentHedgehog^.UnplacedKing then

        TurnTimeLeft:= cHedgehogTurnTime

    else

        TurnTimeLeft:= 0

else

    begin

    if ((GameFlags and gfTagTeam) <> 0) and (not NextClan) then

        begin

        if TagTurnTimeLeft <> 0 then

            TurnTimeLeft:= TagTurnTimeLeft;

        TagTurnTimeLeft:= 0;

        end

    else

        begin

        TurnTimeLeft:= cHedgehogTurnTime;

        TagTurnTimeLeft:= 0;

        NextClan:= false;

        end;

    // Enable switching mode when gfSwitchHog is active

    if ((GameFlags and gfSwitchHog) <> 0) and (not CurrentTeam^.hasGone) and

            // Exception: During the special "Place your King" round in King Mode;

            // you're not supposed to switch away from your king in this round.

            (not (((GameFlags and gfKing) <> 0) and ((GameFlags and gfPlaceHog) = 0) and (TotalRoundsReal = -1))) then

        begin

        g:= AddGear(hwRound(CurrentHedgehog^.Gear^.X), hwRound(CurrentHedgehog^.Gear^.Y), gtSwitcher, 0, _0, _0, 0);

        CurAmmoGear:= g;

        lastGearByUID:= g;

        end

    else

        bShowFinger:= true;

    end;

IsGetAwayTime:= false;

// turn start taunt: sndYesSir for own team, sndHmm for enemy or computer team

if (TurnTimeLeft > 0) and (CurrentHedgehog^.BotLevel = 0) then

    begin

    if (not CinematicScript) then

        if CurrentTeam^.ExtDriven then

            AddVoice(sndHmm, CurrentTeam^.voicepack)

        else

            AddVoice(sndYesSir, CurrentTeam^.voicepack);

    if cHedgehogTurnTime < 1000000 then

        ReadyTimeLeft:= cReadyDelay;

    s:= ansistring(CurrentTeam^.TeamName);